Modifying mp3 metada in reading information from OSX Numbers

[DPaquin]

Thanks for the questions, you make me think further.

CONTEXT:
The mp3 files are not music file to be loaded permanently in a music library. Those are to be used within a sport event like a dancing competition. Each participants are to send their music file to the event organiser. Once they are ready to compete their music is being played. Those music files are only to exist for the duration of the event competition.

The need is to change what is displayed when looking at More Info under Get Info.

Title, Authors and Album are the metadata information to be modified by this AppleScript application.

Answering your questions:

1. The mp3 files are not to be loaded into the Music library, not at the moment. The Music application is only to be used to play them. If, at one point, being loaded in the Music Library it would only be for the time of the event competition. They are to be destroyed after completion of the event competition.

2. Music might not be the right application to be used for what I am trying to do.

3. These files are Music media type.

I do not know which application I should be using to modify the metadata of each music file. All music filenames are loaded in Numbers. Manupilation of the spreadsheet and once completed the metadata is to be modified. To do so, in Numbers I am going one row at a time to apply modification of the metadata.

I’ve changed my code to the following. However, I am getting an " Error: File not found -".

The file is there. Does someone have an idea why am I getting this error?

set folderpath to choose folder with prompt "Choose the folder containing the files to rename"
set myFolder to POSIX path of folderpath
--display dialog "myFolder: " & myFolder

tell application "Numbers"
	-- In Numbers the first table is Table 1.  It is hard to know this because the table most likely does not have its name appear, but the active sheet in a new Number file is Table 1.  There can be multiple tables on a sheet.  Therefore you need to designate the document (file) sheet, and table before you can access attributes
	tell table 1 of active sheet of front document
		
		-- For each row for the count of cells in the first column
		repeat with i from 2 to count of cells of column 1
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusiue
			set newTitle to value of cell i of column "D" -- Titre
			set newArtist to value of cell i of column "C" -- Catégorie
			set newAlbum to value of cell i of column "E" -- Album
			
			set MusicFilename to quoted form of (myFolder & (NomFichierMusique))
			display dialog MusicFilename
			
			do shell script "/usr/local/bin/exiftool -title='" & newTitle & "' -album='" & newAlbum & "' -artist='" & newArtist & "' " & quoted form of MusicFilename
		end repeat
		
	end tell
	
end tell

[Mockman]

Unfortunately, exiftool cannot write such tags (ID3) to mp3 files — it is read only.

You can confirm for your version by viewing the man page for exiftool under the Description in the File Types table. Or you could search for ‘MP3’ by typing the following and ‘enter’:

/MP3

[Mockman]

So the ‘not found’ error is probably because you have two quoted form of: both in the .set MusicFilename to quoted form… line, and also in the do shell script… line.

Remove one and try again.

But then you will likely encounter an Writing of MP3 files is not yet supported error.

Two small points related to do shell script:

First, add a use scripting additions line to the top of the script.

Second, if you put the line inside a tell block, preface it with tell me to, like so:

`tell me to do shell script`…

It is hidden but you will generate a privilege error (-10004) otherwise.

[DPaquin]

You are correct, I did get an “Writing of MP3 files is not yet supported”.

I am back in using Music. I’ve tried this code and now have the following message : error “Can’t set name of "/" to "0101 - Pauline McGregor".” number -10006 from name of “/”

set folderpath to choose folder with prompt "Choose the folder containing the files to rename"
set myFolder to POSIX path of folderpath
--display dialog "myFolder: " & myFolder

tell application "Numbers"
	-- In Numbers the first table is Table 1.  It is hard to know this because the table most likely does not have its name appear, but the active sheet in a new Number file is Table 1.  There can be multiple tables on a sheet.  Therefore you need to designate the document (file) sheet, and table before you can access attributes
	tell table 1 of active sheet of front document
		
		-- For each row for the count of cells in the first column
		repeat with i from 2 to count of cells of column 1
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusiue
			set newTitle to value of cell i of column "D" -- Titre
			set newArtist to value of cell i of column "C" -- Catégorie
			set newAlbum to value of cell i of column "E" -- Album
			
			set MusicFilename to (myFolder & (NomFichierMusique))
			display dialog MusicFilename
			
			tell application "Music"
				-- Get the currently selected track
				set selectedTrack to first item of (get MusicFilename)
				
				-- Change the track's name, artist, and album
				set name of selectedTrack to newTitle
				set artist of selectedTrack to newArtist
				set album of selectedTrack to newAlbum
			end tell
			
			--do shell script "/usr/local/bin/exiftool -title='" & newTitle & "' -album='" & newAlbum & "' -artist='" & newArtist & "' " & quoted form of MusicFilename
		end repeat
		
	end tell
	
end tell

[Mockman]

You’re trying to get something that wasn’t set, so it’s improvising.

The first item of command is actually getting the first character of the path string (ie MusicFilename). It is not getting the first file in the folder.

Run these lines in a new script and you should see what I mean.

set folderpath to choose folder with prompt "Choose the folder containing the files to rename"
set myFolder to POSIX path of folderpath
--> /Users/username/Desktop/musicalstuff/

items of myFolder
--> {"/", "U", "s", "e", "r", "s", "/",…

Here is one way that you might get the files:

set myf to choose folder
tell application "Finder"
	set fileList to (files of myf whose name extension is "mp3") as alias list
end tell

repeat with fl in fileList
	set selectedTrack to item 1 of fileList
end repeat

[Mockman]

Here is a script that does most of what you want. It doesn’t do the tagging because I’m not really sure how you want to do that.

It requires a folder with the mp3 files and a Numbers spreadsheet with matching filenames. What it does is make a list of mp3 files and another of the matching metadata. It then cycles through the list of files and then grabs the corresponding data.

use scripting additions
set myf to choose folder
tell application "Finder"
	set rowCt to 1
	set fileList to (files of myf whose name extension is "mp3") as alias list
	repeat with fl in fileList -- cycle through song files
		set selectedTrack to contents of fl
		--> alias "MacHD:Users:username:Desktop:qisum:0123456789-ADP35ARG.mp3"
		set fileName to name of selectedTrack
		--> "0123456789-ADP35ARG.mp3"		
		
		set nomList to my getColumnData() -- list of mp3 file names
		set rowCt to rowCt + 1 -- counter of rows in above list
		repeat with lineItem in (get rest of nomList) -- ignores headings
			if contents of lineItem is equal to fileName then -- find matching row in table
				set eachTrack to my acquireMeta(rowCt) -- acquire metadata
				--> {"0101 - Pauline McGregor", "ADP35ARG", "Adulte intro"}
				exit repeat
			end if
		end repeat
		
	end repeat
end tell


-- takes row number, returns NomFichierMusique, _Title, _Category, _Album
on acquireMeta(i)
	tell application "Numbers"
		tell table 1 of active sheet of front document
			
			set NomFichierMusique to value of cell i of column "A" -- NomFichierMusique
			set _Title to value of cell i of column "B" -- Titre
			set _Category to value of cell i of column "C" -- Catégorie
			set _Album to value of cell i of column "D" -- Albun			
			
		end tell
	end tell
	return {_Title, _Category, _Album}
end acquireMeta
-- NB requires appropriate Numbers document 

-- returns list of NomFichierMusique; looks for correct column then returns list including heading;
on getColumnData()
	tell application "Numbers"
		tell table 1 of active sheet of front document
			set nfm to "NomFichierMusique"
			set keyCol to column of first cell of row 1 whose value is nfm -- determine correct column
			
			set tbl to value of cells of keyCol -- get values of column, including heading
			{"NomFichierMusique", "0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			if item 1 of tbl is "NomFichierMusique" then
				set val to tbl -- set val to rest of tbl
				--> {"0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			else -- in case the table has changed
				display dialog "This is actually the " & item 1 of tbl & " column"
			end if
		end tell
	end tell
end getColumnData
-- NB requires appropriate Numbers document 

Regarding the handlers, you can inspect them by putting either of them in a new script and removing the ‘on’ statements and then, for the metadata handler, setting a variable for the row number the spreadsheet to grab.

[DPaquin]

We are progressing.

I am now getting this error : Music got an error: Unknown object type. when executing

set name of selectedTrack to newTitle

set myf to choose folder with prompt "Choose the folder with MP3 metadata to be modified"
set myFolder to POSIX path of myf

tell application "Finder"
	set fileList to (files of myf whose name extension is "mp3") as alias list
	set itemCount to count of fileList
end tell

tell application "Numbers"

	tell table 1 of active sheet of front document
		
		repeat with i from 2 to count of cells of column 1
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusiue
			set newTitle to value of cell i of column "D" -- Titre
			set newArtist to value of cell i of column "C" -- Catégorie
			set newAlbum to value of cell i of column "E" -- Album
			set NumbersFilename to (myFolder & (NomFichierMusique))
			
			repeat with fl from 1 to count of fileList
				set selectedTrack to item fl of fileList
				set foldertrack to POSIX path of selectedTrack
				if NumbersFilename = foldertrack then
					tell application "Music"
						display dialog "Changing metadata"
						-- Change the track's name, artist, and album
						set name of selectedTrack to newTitle
						set artist of selectedTrack to newArtist
						set album of selectedTrack to newAlbum
					end tell
				end if
			end repeat
		end repeat
	end tell
end tell

[Mockman]

That error is not a listed one.

Online, people think it relates to sandboxing.

But in this case, I think that it is because you are trying to feed the Music app an ‘alias’ object, and apparently this is foreign.

At that point, you have to work with Music objects and kit.

To Music, it is not a file, it is a track. So you have to change the name of the track, and to do that, you must specify the track.

[Mockman]

For anyone who is interested in ffmpeg, I would recommend using one of the macos packaging tools to install, such as Macports (or the Fink or homebrew).

You might also find an ID3 editor through one of these services, which would be much lighter and more focused. ffmpeg is overkill for such a task.

And no quicktime player please, (unless you want to do a quick screen recording).

[DPaquin]

Wow ! Many Thanks!

This is a very nice code.

In the end I am going to use the Music App. I am getting error "The variable _Title is not defined.

I’ve added a display dialog in the «acquireMeta» and the title value does contain information. I do not understand why the return {_Title, _Category, _Album} does not return any information.

I’ve also added a display dialog right after the call of «acquireMeta» and nothing got returned. Everything seems to be ok and why nothing is being returned?

Many thanks!

use scripting additions
set myf to choose folder
tell application "Finder"
	set rowCt to 1
	set fileList to (files of myf whose name extension is "mp3") as alias list
	repeat with fl in fileList -- cycle through song files
		set selectedTrack to contents of fl
		--> alias "MacHD:Users:username:Desktop:qisum:0123456789-ADP35ARG.mp3"
		set fileName to name of selectedTrack
		--> "0123456789-ADP35ARG.mp3"	
		--display dialog "Main() " & fileName
		
		set nomList to my getColumnData() -- list of mp3 file names
		set rowCt to rowCt + 1 -- counter of rows in above list
		repeat with lineItem in (get rest of nomList) -- ignores headings
			if contents of lineItem is equal to fileName then -- find matching row in table
				set eachTrack to my acquireMeta(rowCt) -- acquire metadata
				--> {"0101 - Pauline McGregor", "ADP35ARG", "Adulte intro"}
                               display dialog "Changing metadata selectedTrack: " & selectedTrack & "/nTitle: " & _Title & " Category: " & _Category & " Album: " & _Album
				tell application "Music"
					display dialog "Changing metadata"
					-- Change the track's name, artist, and album
					set name of selectedTrack to _Title
					set artist of selectedTrack to _Category
					set album of selectedTrack to _Album
				end tell
				exit repeat
			end if
		end repeat
		
	end repeat
end tell


-- takes row number, returns NomFichierMusique, _Title, _Category, _Album
on acquireMeta(i)
	--display dialog "acquireMeta(i)" & i
	tell application "Numbers"
		tell table 1 of active sheet of front document
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusique
			set _Title to value of cell i of column "D" -- Titre
			set _Category to value of cell i of column "C" -- Catégorie
			set _Album to value of cell i of column "E" -- Albun			
			display dialog "NomFichierMusique: " & NomFichierMusique & " _Title: " & _Title & " _Category: " & _Category & " _Album: " & _Album
		end tell
	end tell
	return {_Title, _Category, _Album}
end acquireMeta
-- NB requires appropriate Numbers document 

-- returns list of NomFichierMusique; looks for correct column then returns list including heading;
on getColumnData()
	tell application "Numbers"
		tell table 1 of active sheet of front document
			set nfm to "NomFichierMusique"
			set keyCol to column of first cell of row 1 whose value is nfm -- determine correct column
			
			set tbl to value of cells of keyCol -- get values of column, including heading
			--display dialog "getColumnData() tbl: " & tbl
			{"NomFichierMusique", "0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			if item 1 of tbl is "NomFichierMusique" then
				set val to tbl -- set val to rest of tbl
				--> {"0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			else -- in case the table has changed
				display dialog "This is actually the " & item 1 of tbl & " column"
			end if
		end tell
	end tell
end getColumnData
-- NB requires appropriate Numbers document 

[Mockman]

Thanks. Hope this works.

By the way, the variable _Title isn’t created inside the handler although the data gets determined there. It gets created when you set ‘_Title’ to the results of the handler. Obviously, you have to line up the various bits and pieces.

As to the object problem… take this code, put it in an empty script and run it. A song must be selected in Music for it to work (and it must be one that’s stored on the drive, not streamed).

tell application "iTunes"
	set x to current track
	--> file track id 123456 of user playlist id 4321 of source id 66
end tell

You can see that a reference to a song is part of a chain. So we have to figure out how to reference the Library (source) and the Music playlist (user playlist) before we can specify the individual track. Note that when you get a track, you will also get its playlist and library. I added a handler that gets the playlist ID for the ‘Music’ playlist.

Ultimately, setting the properties will look something like this:

set name of file track id 41539 of user playlist id 23420 of ¬
		source id 66 to "123456789-ADP35ARG"

So here is what seems to work for me in itunes. Should work in Music as well.

use scripting additions
set musicPlaylist to getLibaryPlaylist()
--> user playlist id 34220 of source id 65

set myf to choose folder
tell application "Finder"
	set rowCt to 1
	set fileList to (files of myf whose name extension is "mp3") as alias list -- list of mp3 files as aliases
	repeat with fl in fileList -- cycle through song files
		set selectedTrack to contents of fl
		--> alias "MacHD:Users:username:Desktop:qisum:0123456789-ADP35ARG.mp3"
		set fileName to name of selectedTrack -- inside Music, the name of the track should not have any extension
		--> "0123456789-ADP35ARG.mp3"	
		set AppleScript's text item delimiters to ".mp3"
		set trackName to first text item of fileName -- strip extension from track name
		set AppleScript's text item delimiters to {""}
		
		set nomList to my getColumnData() -- list of mp3 file names
		set rowCt to rowCt + 1 -- counter of rows in above list
		repeat with lineItem in (get rest of nomList) -- ignores headings
			if contents of lineItem is equal to fileName then -- find matching row in table
				set eachTrack to my acquireMeta(rowCt) -- acquire metadata
				log "eachtrack: " & eachTrack
				--> {"0101 - Pauline McGregor", "ADP35ARG", "Adulte intro"}
				tell application "iTunes"
					activate
					-- display dialog "Changing metadata"
					-- Change the track's name, artist, and album
					set ttn to track trackName of musicPlaylist
					log ttn
					set name of ttn to item 2 of eachTrack
					set artist of ttn to item 1 of eachTrack
					set album of ttn to item 3 of eachTrack
				end tell
				delay 0.2
				exit repeat
			end if
		end repeat
		
	end repeat
end tell


-- takes row number, returns NomFichierMusique, _Title, _Category, _Album
on acquireMeta(i)
	--display dialog "acquireMeta(i)" & i
	tell application "Numbers"
		tell table 1 of active sheet of front document
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusique
			set _Title to value of cell i of column "D" -- Titre
			set _Category to value of cell i of column "C" -- Catégorie
			set _Album to value of cell i of column "E" -- Albun			
			
		end tell
	end tell
	return {_Title, _Category, _Album}
end acquireMeta
-- NB requires appropriate Numbers document 

-- returns list of NomFichierMusique; looks for correct column then returns list including heading;
on getColumnData()
	tell application "Numbers"
		tell table 1 of active sheet of front document
			set nfm to "NomFichierMusique"
			set keyCol to column of first cell of row 1 whose value is nfm -- determine correct column
			
			set tbl to value of cells of keyCol -- get values of column, including heading
			--display dialog "getColumnData() tbl: " & tbl
			{"NomFichierMusique", "0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			if item 1 of tbl is "NomFichierMusique" then
				set val to tbl -- set val to rest of tbl
				--> {"0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			else -- in case the table has changed
				display dialog "This is actually the " & item 1 of tbl & " column"
			end if
		end tell
	end tell
end getColumnData
-- NB requires appropriate Numbers document 

-- get Music hierarchy
on getLibaryPlaylist()
	tell application "iTunes"
		set sid to source "Library"
		
		set pm to playlist "Music" of sid
		--> user playlist id 34220 of source id 65 of application "iTunes"
		set sk to first item of (playlists whose special kind is Music)
		if pm is equal to sk then
			set musicPlaylist to sk
		end if
	end tell
	return musicPlaylist
end getLibaryPlaylist

[technomorph]

For sure Exif Tool can write mp3 meta data

Best bet is Kid3 tag editor
Can work with CSV file and write meta data fairly easily.

[DPaquin]

Thanks for this code. This is greatly appreciated. Not a chance I would have been able to write such a code.

Unfortunately I am getting a Syntax Error “Expected end of line, etc. but found identifier.” at line → set ttn to track trackName of musicPlaylist

Note: I’ve installed iTunes on my MAC.

[Mockman]

@DPaquin

Syntax Error “Expected end of line, etc. but found identifier.”

That typically means that you’re missing a closing double quote somewhere. The compiler (I’m guessing) keeps looking for and eventually finds the opening quotes of another string and flags the subsequent text because it isn’t ‘inside’ any quotes.

Here is a an example that should provide some insight. Notice that there aren’t any closing quotes on line 2. So the compiler will keep looking until it finds the opening quotes on line 3 and then assumes that they’re really the missing closing quotes from line 2. You can run it in a new script to see what I mean.

set x to "3"
set y to "4
set z to "5"

So what the compiler sees is something like this:

set x to "3"
set y to "4
set z to "

Followed by this, which is obviously an error and this is what gets flagged.

5"

Of course, the problem actually occurs earlier but the compiler makes do with what it has and this is the point where it must be an error.

So, take a quick look for missing quotes after the previous quotes but before the highlighted text.

Regarding iTunes… I should have swapped ‘Music’ in for it. The script should work with Music if you change all the iTunes references. FWIW though, the missing quotes could be at the word ‘iTunes’.

[DPaquin]

Thanks again. I’ve only changed all instances of iTunes to Music and it compiled without any problems.

I got it to work. However, I had to make changes to the file which was imported to Music.

To get it to work the osx filename and there music title must be the same without mp3 “0123456789-ADP35ARG” which is not the case. The music file comes from people participating to a sport event. They only rename their music files to respect some standard without changing the title.

The changes being made to the metadata are being done within Music not affecting the OSX filename. When doing a OSX get info on the file the metadata is still the same. I guess I would have to export the song from Music to have the OSX metadata being changed as required.

Is there a way to change the metadata of a mp3 file in Finder without going to Music?

[Mockman]

Can you specify what it is that you want to change? The short answer is yes.

[DPaquin]

Thanks again!

I want to change the Title, Subtitle and Album metadata information of mp3 files to values found in the Numbers spreadsheet.

In the meantime initialize Rating, Comments, Contributing Artis, Album artist, Year, #, Genre, Publisher, Encoded by, Author URL, Copyright… to blanks I.e no values.

I wish to be able to do this at the file level.

I changed the code in using kid3-cli. It does execute properly. Unfortunately, the metadata does not change.

Regards!

use scripting additions
-- Path to the kid3-cli executable within the Kid3 application bundle
-- Path to the kid3-cli executable within the Kid3 application bundle
set kid3CLIpath to "Macintosh HD:Applications:kid3.app:Contents:MacOS:kid3-cli"
set kid3CliAlias to alias kid3CLIpath

-- Check if kid3-cli exists, display error if not
if not (exists kid3CliAlias) then
	display dialog "kid3-cli not found at " & kid3CLIpath & ". Please check the path." buttons {"OK"} default button "OK"
	return
end if

set myf to choose folder
set filePath to POSIX path of myf

tell application "Finder"
	set rowCt to 1
	set fileList to (files of myf whose name extension is "mp3") as alias list -- list of mp3 files as aliases
	repeat with fl in fileList -- cycle through song files
		set selectedTrack to contents of fl
		--> alias "MacHD:Users:username:Desktop:qisum:0123456789-ADP35ARG.mp3"
		set fileName to name of selectedTrack -- inside Music, the name of the track should not have any extension
		--> "0123456789-ADP35ARG.mp3"
		
		set AppleScript's text item delimiters to ".mp3"
		set trackName to first text item of fileName -- strip extension from track name
		set AppleScript's text item delimiters to {""}
		
		set nomList to my getColumnData() -- list of mp3 file names
		set rowCt to rowCt + 1 -- counter of rows in above list
		repeat with lineItem in (get rest of nomList) -- ignores headings
			if contents of lineItem is equal to fileName then -- find matching row in table
				set eachTrack to my acquireMeta(rowCt) -- acquire metadata
				display dialog "eachTrack" & eachTrack & " lineItem: " & lineItem & "filePath: " & filePath
				set _title to item 2 of eachTrack
				set _Category to item 1 of eachTrack
				set _album to item 3 of eachTrack

				set shellCommand to quoted form of (POSIX path of kid3CLIpath) & " " & quoted form of (filePath & fileName) & " set artist " & quoted form of _title & " set album " & quoted form of _album & " set author " & quoted form of _Category & " save"
				display dialog "shellCommand: " & shellCommand
				-- Execute the command using do shell script
				try
					do shell script shellCommand
					display notification "Updated tags for: " & quoted form of (filePath & fileName) with title "Kid3 Tagger"
				on error errMsg
					display dialog "Error updating tags for file " & quoted form of (filePath & fileName) & ": " & errMsg buttons {"OK"} default button "OK"
				end try
				delay 0.2
				exit repeat
			end if
		end repeat
		
	end repeat
end tell


-- takes row number, returns NomFichierMusique, _Title, _Category, _Album
on acquireMeta(i)
	--display dialog "acquireMeta(i): " & i
	tell application "Numbers"
		tell table 1 of active sheet of front document
			
			set NomFichierMusique to value of cell i of column "B" -- NomFichierMusique
			set _title to value of cell i of column "D" -- Titre
			set _Category to value of cell i of column "C" -- Catégorie
			set _album to value of cell i of column "E" -- Albun			
			
		end tell
	end tell
	--display dialog "NomFichierMusique: " & NomFichierMusique & " _Title: " & _title & " _Category: " & _Category & " _Album: " & _album
	return {_title, _Category, _album}
end acquireMeta
-- NB requires appropriate Numbers document 

-- returns list of NomFichierMusique; looks for correct column then returns list including heading;
on getColumnData()
	tell application "Numbers"
		tell table 1 of active sheet of front document
			set nfm to "NomFichierMusique"
			set keyCol to column of first cell of row 1 whose value is nfm -- determine correct column
			
			set tbl to value of cells of keyCol -- get values of column, including heading
			--display dialog "getColumnData() tbl: " & tbl
			{"NomFichierMusique", "0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			if item 1 of tbl is "NomFichierMusique" then
				set val to tbl -- set val to rest of tbl
				--> {"0123456789-ADP35ARG.mp3", "1234567890-ASTAR5.mp3"}
			else -- in case the table has changed
				display dialog "This is actually the " & item 1 of tbl & " column"
			end if
		end tell
	end tell
end getColumnData
-- NB requires appropriate Numbers document 

[Mockman]

The script I posted should work with Music if you change every instance of “iTunes” to “Music”.

As to the command-line method, I’m not familiar with the kid3 tool so I can’t advise.

A couple of general suggestions about shell scripts though… first, remove the try command lines before you run your script. They obscure what is happening. Add them back in once you have the script working. If you’re going to troubleshoot a problem you need to see what’s going on.

Second, get the command working in the terminal first. Then compare the working command with the result of shellCommand. There will likely be differences due to quoting but otherwise they should be consistent.

Third, prepend this to the do shell script line: 'tell me to ', so it looks like this:

    tell me to do shell script shellCommand

In general, you should avoid putting ‘do shell script’ inside any application tell blocks but if you must, then use that.

FWIW, you could also make a tell block, like so:

	tell me
		do shell script shellCommand
	end tell

Hope it works out.

[technomorph]

For initial trials I would get a test string made up from you data the actiual shell command. And test it in terminal.

From what I remember your syntax is not full correct. You need to select one of the frames, which is usually 2. Also you need to add “-c” to tell it to execute a command.

Here’s an example setting the LABEL tag on frame 2

kid3-cli -c "set LABEL 'FLAC 16bit/44.1khz' 2" "/Volumes/Tekno/Users/kerry/Music/iTunes/iTunes Media/Music/The White Stripes/My Doorbell - EP/My Doorbell.mp3"

It Gets trickier setting multiple tags. I usually use the JSON format which also helps make
Setting all of your double and single
Quotes properly.

 kid3-cli -c {"method": "set","parameters":["LABEL","AAC 320kbps/44.1khz",2]} -c {"method": "set","parameters": ["CATALOGNUMBER", "5491D60BAD7C3C71", 2]} "/Volumes/Tekno/Users/kerry/Music/iTunes/iTunes Media/Music/The White Stripes/My Doorbell - EP/My Doorbell.mp3"

I’m not sure how shell scripts work with the alias file path format “volume:folder:file” you may want to change that.

In kid3-cll interface it gets trickey when you have spaces…. It pretty much breaks
All of the “args” commands / tags / values by space.

So this will work:

kid3-cli -c set ARTIST Lumberjacks 2 "/Volumes/Tekno/Users/kerry/Music/iTunes/iTunes Media/Music/The White Stripes/My Doorbell - EP/My Doorbell.mp3"

This will not with space in the TAG value

kid3-cli -c set ARTIST Earth Wind and Fire 2 "/Volumes/Tekno/Users/kerry/Music/iTunes/iTunes Media/Music/The White Stripes/My Doorbell - EP/My Doorbell.mp3"

This will not with space in the FILE path:

kid3-cli -c set ARTIST Lumberjacks 2 Volumes/Tekno/Users/kerry/Music/iTunes/iTunes Media/Music/The White Stripes/My Doorbell - EP/My Doorbell.mp3

Using the JSON format keys things easy by just double quoting everything

[technomorph]

Also I would symlink the executable
To your use/local/bin.
Use this in terminal:

sudo ln -s /Applications/kid3.app/Contents/MacOS/kid3-cli /usr/local/bin

Then you just need to call “kid3-cli” from your Shell Sceipt rather than that full path.