Scripting New iTunes 11 - item of pop up button

kiwilegal · December 2, 2012, 5:05pm

OK. I got Yvan’s script working. As was pointed out, needs side bar activated…

And works for connecting to home share libraries.

But if there is a direct way to reference home share libraries using iTunes dictionary, I would be keen to know/learn.

Basically, I want my iTunes on Macbook to auto connect to main iTunes library on server whenever it is launched.

Cheers

Yvan_Koenig · December 2, 2012, 6:10pm

Just for the fun, this version is supposed to work in both cases.


tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		set needShortcut to false
		try
			position of first pop up button of window 1
			# Here if the sidebar is unavailable
			set needShortcut to true
			# Show the sidebar
			keystroke "s" using {option down, command down}
			delay 0.1
		end try
		
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) contains "TV")
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		# Hide the sidebar if we revealed it
		if needShortcut then keystroke "s" using {option down, command down}
	end tell # process
end tell # System Events

Bien le bonjour de Vallauris

Yvan KOENIG (VALLAURIS, France) dimanche 2 dÃ©cembre 2012 19:09:56

kiwilegal · December 2, 2012, 7:03pm

Hi Yvan

I had cobbled together the following script, built around your script, which works:

tell application "iTunes" to activate
tell application "System Events"
	tell application process "iTunes"
		try
			click menu item "Show Sidebar" of menu 1 of menu bar item "View" of menu bar 1
			delay 1
		end try
		tell window 1
			try
				click (first button whose name is not missing value and name is not "iTunes Store")
			end try
		end tell # window 1
		
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			repeat with n from 1 to 10
				try
					(first row whose value of (static text 1) contains "Server")
					set value of attribute "AXSelected" of result to true
					delay 1
					exit repeat
				end try
				delay 1
			end repeat
		end tell # window 1
		try
			click menu item "Hide Sidebar" of menu 1 of menu bar item "View" of menu bar 1
		end try
		--delay 10
	end tell # process
end tell # System Events

I have it autorun, using DSW, when iTunes launches and all seems to work well, irrespective of how iTunes is set up.

Of course, if there is an iTunes dictionary solution, that would be much better. But in the meantime, we have a solution.

Bien Ã vous et merci depuis le Limousin…

StefanK · December 2, 2012, 7:24pm

Hi,

I recommend to control showing and hiding the sidebar rather than using try blocks


activate application "iTunes"
tell application "System Events"
	tell application process "iTunes"
		set sidebarIsVisible to exists splitter group 1 of window 1
		if not sidebarIsVisible then
			keystroke "s" using {command down, option down} -- show sidebar
			repeat until exists splitter group 1 of window 1
				delay 0.2
			end repeat
		end if
		
		-- .
		
		if not sidebarIsVisible then
			keystroke "s" using {command down, option down} -- hide sidebar
		end if
	end tell # process
end tell # System Events

kiwilegal · December 2, 2012, 7:25pm

Thanks, Stefan

No top tips for direct action under iTunes dictionary to connect to home share library:)

A

StefanK · December 2, 2012, 7:39pm

I don’t use home sharing.

If the library is not treated as a playlist, there’s no way to access it via iTunes dictionary

kiwilegal · December 2, 2012, 7:58pm

OK. Glad to clear that up:)

Thanks

Nigel_Garvey · December 2, 2012, 8:13pm

StefanK:

I recommend to control showing and hiding the sidebar rather than using try blocks


activate application "iTunes"
tell application "System Events"
	tell application process "iTunes"
		set sidebarIsVisible to exists splitter group 1 of window 1
		if not sidebarIsVisible then .

On my Snow Leopard System (the one where my GUI script works), the main window of iTunes 11.0 has a splitter group 1 whether the sidebar’s showing or not. It would probably be better to test to test if ‘(splitter group 1 of splitter group 1 of window 1 exists)’ or if ‘(name of static text of rows of outline 1 of scroll area 1 of splitter group 1 of window 1 contains {{“Home Sharing”}})’.

StefanK · December 2, 2012, 8:16pm

Thanks, I tested it only on Lion

Yvan_Koenig · December 2, 2012, 9:41pm

Nigel Garvey:

StefanK:
I recommend to control showing and hiding the sidebar rather than using try blocks
activate application "iTunes"
tell application "System Events"
	tell application process "iTunes"
		set sidebarIsVisible to exists splitter group 1 of window 1
		if not sidebarIsVisible then .
On my Snow Leopard System (the one where my GUI script works), the main window of iTunes 11.0 has a splitter group 1 whether the sidebar’s showing or not. It would probably be better to test to test if ‘(splitter group 1 of splitter group 1 of window 1 exists)’ or if ‘(name of static text of rows of outline 1 of scroll area 1 of splitter group 1 of window 1 contains {{“Home Sharing”}})’.

Hello Nigel

I’m not sure that testing the availability of the string “Home Sharing” is a good idea.
As you will see below, it’s a localizable string.
EDIT : As I don’t use this feature, Home Sharing/Partage Ã domicile, is not displayed on my copy.
One more reason to don’t use it as a state flag

In fact I was back here to post a short piece of code able to grab some localized strings :


set beg to "163.0"
set local_items to {}
repeat with i from 86 to 91
	tell application "iTunes" to localized string (beg & i)
	set end of local_items to beg & i & " : " & result
end repeat
local_items
--> {"163.086 : Musique", "163.087 : Films", "163.088 : SÃ©ries TV", "163.089 : Podcasts", "163.090 : Livres", "163.091 : Apps"}

tell application "iTunes" to set TV_local to localized string (beg & 88)
--> "SÃ©ries TV"

tell application "iTunes" to set HomeSharing_local to localized string "9000.040"
--> "Partage Ã  domicile"
tell application "iTunes" to set HomeSharing_local to localized string "kMenuItemSharing"
--> "Partage Ã  domicile"

Maybe a test upon the pop up button would be OK for the different systems.
It behave flawlessly with Mountain Lion.


tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		set needShortcut to false
		if (exists pop up button 1 of window 1) then
			# Here if the sidebar is unavailable
			set needShortcut to true
			# Show the sidebar
			keystroke "s" using {option down, command down}
			delay 0.1
		end if
		
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) contains "TV")
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		# Hide the sidebar if we revealed it
		if needShortcut then keystroke "s" using {option down, command down}
	end tell # process
end tell # System Events

Other scheme : test the status of the menu item ruling the sidebar :


tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		set {mt, mi} to {5, 5} # PrÃ©sentation > Masquer ou Afficher la barre latÃ©rale
		tell menu bar 1 to tell menu bar item mt to tell menu 1
			set needShortcut to get enabled of menu item mi
			if needShortcut then click menu item mi
		end tell -- menu bar.
		
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) contains "TV")
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		# Hide the sidebar if we revealed it
		if needShortcut then keystroke "s" using {option down, command down}
	end tell # process
end tell # System Events

Alas I don’t know, if the menu is the same under the different OS.

Yvan KOENIG (VALLAURIS, France) dimanche 2 dÃ©cembre 2012 22:41:48

Nigel_Garvey · December 3, 2012, 12:06am

Hi Yvan. Yes. Sorry. I was aware of that when I posted. But I was watching something on television and reckoned you’d know more about localised strings than I do.

I don’t use it either ” in fact, I rarely use iTunes at all ” but “Home Sharing” is displayed in my copy.

Except that, as I mentioned somewhere above, it’s not a pop up button on my machine but an ordinary button which looks similar to a pop up.

That should be the best method, but the only difference in the menu item here is the verb in the name.

But that’s the nature of GUI Scripting. At least it sounds as if kiwilegal’s got something that will serve the turn until the next iTunes or system update.

Yvan_Koenig · December 3, 2012, 9:58am

Hello

Happily, it’s easy to grab the localized string used to display the menu items.

“kMenuItemShowSourcesList” = “Afficher la barre latÃ©rale###S#option”;
“kMenuItemHideSourcesList” = “Masquer la barre latÃ©rale###S#option”;

So, to check if we must issue the shortcut we just need to check if the local value of the string “kMenuItemShowSourcesList” contains the name of the 5th menu item.


tell application "iTunes" to set showSidebar_local to localized string "kMenuItemShowSourcesList"
--> "Afficher la barre latÃ©rale###S#option"
(*
tell application "iTunes" to set hideSidebar_local to localized string "kMenuItemHideSourcesList"
--> "Masquer la barre latÃ©rale###S#option"
*)
tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		set {mt, mi} to {5, 5} # PrÃ©sentation > Masquer ou Afficher la barre latÃ©rale
		tell menu bar 1 to tell menu bar item mt to tell menu 1
			name of menu item mi
			--> "Afficher la barre latÃ©rale" ou "Masquer la barre latÃ©rale"
			set needShortcut to showSidebar_local contains result
		end tell -- menu bar.
		if needShortcut then keystroke "s" using {option down, command down}
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) contains "TV")
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		# Hide the sidebar if we revealed it
		if needShortcut then keystroke "s" using {option down, command down}
	end tell # process
end tell # System Events

Just for info,
in Japanese:
“kMenuItemShowSourcesList” = “ã‚µã‚¤ãƒ‰ãƒãƒ¼ã‚’è¡¨ç¤º###S#option”;
“kMenuItemHideSourcesList” = “ã‚µã‚¤ãƒ‰ãƒãƒ¼ã‚’éš ã™###S#option”;
in Russian:
“kMenuItemShowSourcesList” = “ÐŸÐ¾ÐºÐ°Ð·Ð°Ñ‚ÑŒ Ð±Ð¾ÐºÐ¾Ð²Ð¾Ðµ Ð¼ÐµÐ½ÑŽ###S#option”;
“kMenuItemHideSourcesList” = “Ð¡ÐºÑ€Ñ‹Ñ‚ÑŒ Ð±Ð¾ÐºÐ¾Ð²Ð¾Ðµ Ð¼ÐµÐ½ÑŽ###S#option”;

Yvan KOENIG (VALLAURIS, France) lundi 3 dÃ©cembre 2012 10:58:30

Nigel_Garvey · December 3, 2012, 10:12am

. or the 4th in Snow Leopard.

Edit: Here’s another idea:

tell application "System Events"
	tell application process "iTunes"
		set frontmost to true
		set sidebarMenuItem to first menu item of menu 1 of menu bar item 5 of menu bar 1 whose (value of attribute "AXMenuItemCmdChar" is "S") and (value of attribute "AXMenuItemCmdModifiers" is 2)
	end tell
end tell

Yvan_Koenig · December 3, 2012, 4:16pm

Nigel Garvey:

Yvan Koenig:

So, to check if we must issue the shortcut we just need to check if the local value of the string “kMenuItemShowSourcesList” contains the name of the 5th menu item.

. or the 4th in Snow Leopard.

Edit: Here’s another idea:
tell application "System Events"
	tell application process "iTunes"
		set frontmost to true
		set sidebarMenuItem to first menu item of menu 1 of menu bar item 5 of menu bar 1 whose (value of attribute "AXMenuItemCmdChar" is "S") and (value of attribute "AXMenuItemCmdModifiers" is 2)
	end tell
end tell

Thanks Nigel

Which are the menu items in Snow ?
Did they reverted sidebar and statusbar or was the statusbar item unavailable ?

This edited version seems to be safe (assuming that the user didn’t change it’s shortcut ;))



tell application "iTunes" to set showSidebar_local to localized string "kMenuItemShowSourcesList"
--> "Afficher la barre latÃ©rale###S#option"
(*
tell application "iTunes" to set hideSidebar_local to localized string "kMenuItemHideSourcesList"
--> "Masquer la barre latÃ©rale###S#option"
*)
tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		name of first menu item of menu 1 of menu bar item 5 of menu bar 1 whose (value of attribute "AXMenuItemCmdChar" is "S") and (value of attribute "AXMenuItemCmdModifiers" is 2)
		--> "Afficher la barre latÃ©rale" ou "Masquer la barre latÃ©rale"
		set needShortcut to showSidebar_local contains result
		
		if needShortcut then keystroke "s" using {option down, command down}
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) contains "TV")
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		# Hide the sidebar if we revealed it
		if needShortcut then keystroke "s" using {option down, command down}
	end tell # process
end tell # System Events

Nigel_Garvey · December 3, 2012, 9:41pm

Hi Yvan.

I can’t find any mention of a “statusbar” or status bar.

Yvan_Koenig · December 4, 2012, 10:12am

Hello

Statusbar is available under 10.8.2 and maybe under 10.7.x.

Nigel_Garvey · December 4, 2012, 11:04am

Hi Yvan.

As I’ve just e-mailed you, the iTunes 11.0’s status bar exists in Snow Leopard, but isn’t hideable. The screenshot you sent me shows the hide/show keystroke on your system to be âŒ˜/.

Yvan_Koenig · December 4, 2012, 2:56pm

Oops, I failed to edit the shortcut after a copy/paste of the sidebar row to add the statusbar one

gyuen · December 5, 2012, 3:09am

Exactly what I was looking for. I like Nigel’s reveal playlist method best; it’s simple. Thought it seems none of the methods except using the sidebar work for selecting Apps.

Yvan_Koenig · December 5, 2012, 9:29am

Here is a piece of code extracting the list of every applications




tell application "iTunes" to set showSidebar_local to localized string "kMenuItemShowSourcesList"
--> "Afficher la barre latÃ©rale###S#option"
tell application "iTunes" to set apps_local to localized string "163.091"
--> "Apps"
(*
tell application "iTunes" to set hideSidebar_local to localized string "kMenuItemHideSourcesList"
--> "Masquer la barre latÃ©rale###S#option"
*)
tell application "iTunes" to activate

tell application "System Events"
	tell application process "iTunes"
		name of first menu item of menu 1 of menu bar item 5 of menu bar 1 whose (value of attribute "AXMenuItemCmdChar" is "S") and (value of attribute "AXMenuItemCmdModifiers" is 2)
		--> "Afficher la barre latÃ©rale" ou "Masquer la barre latÃ©rale"
		set needShortcut to showSidebar_local contains result
		
		if needShortcut then keystroke "s" using {option down, command down}
		# Now, speak to the new window 1
		
		tell window 1 to tell outline 1 of scroll area 1 of splitter group 1
			repeat until it exists
				delay 0.2
			end repeat
			(* In French, the target row is « SÃ©ries TV » *)
			(first row whose value of (static text 1) is apps_local)
			set value of attribute "AXSelected" of result to true
		end tell # window 1
		tell window 1 to tell first splitter group
			tell first radio group
				name of radio buttons
				--> {"Tous", "iPhone/iPod touch", "iPad", "Jeux iPod", "Liste"}
				click radio button 5 # Activate List mode
			end tell
			
			tell scroll area -1 to tell outline 1
				value of text field of every row # extract the list of every apps installed
			end tell
			
		end tell
	end tell # process
end tell # System Events