Adding subfolders

I am testing the following script. Is it possible to add subfolders to the folder property folerNames?

For example:
Concept 1 (Top folder)
Assets (Subfolder)
Production (Subfolder)
Review (Subfolder)
Trash (Subfolder)

property folderNames : {“Concept 1”, “Concept 2”, “Concept 3”, “Concept 4”}

set posixPath to text 1 thru -2 of (the clipboard as string)
set hfsPath to posixPath as POSIX file as text

tell application “Finder”

repeat with i in folderNames
	set name of (make new folder at (hfsPath)) to i
end repeat

end tell

The same question was asked & answered here.

set name of (make new folder at folder hfsPath) to contents of i

Can you share an example, please? I am not sure how to set the i.

The shell provides a pretty convenient way to do that

set posixPath to text 1 thru -2 of (the clipboard)
set folderStructure to quoted form of posixPath & "/{'Concept 1','Concept 2','Concept 3','Concept 4'}/{Assets,Production,Review,Trash}"
do shell script "/bin/mkdir -p " & folderStructure

Side note: Getting the path from the clipboard is not reliable. I would prefer choose folder

@StefanK provided best solution. Other choice (using your example logic) was this:

property folderNames : {"Concept 1", "Concept 2", "Concept 3", "Concept 4"}
property subFolderNames : {"Assets", "Production", "Review", "Trash"}

set hfsPath to (choose folder) as text

tell application "Finder"
	repeat with i in folderNames
		set aFolder to make new folder at folder hfsPath with properties {name:(contents of i)}
		repeat with subFolderName in subFolderNames
			make new folder at aFolder with properties {name:(contents of subFolderName)}
		end repeat
	end repeat
end tell

Note: I am not sure, but it seems to me, it can be useful if you don’t want to grant full disk access to mkdir command (for some special locations). But, as I sad, generally I see the solution from @StefanK better than Finder solution.

Thank you, I finally had time to test the solution from StephenK, and works great. Also, thank you for the additional suggestions to make a precise script!