Adobe Creative Suite 2 Uninstallation Script

sprale · June 23, 2010, 9:38pm

Since Adobe doesn’t provide a solution for the average user to remove CS2 completely, I’ve put a script together to resolve this for myself, figured I may as well share with the community. It’s nothing fancy, pure vanilla, but was a bit time-consuming to put together. Hopefully someone gets use out of it.


-- I've built this script based upon the Adobe TechNote for Creative Suite 2. Adobe has not official uninstaller, nor does the installer perform this function. This script is a bit of a blunt instrument, removing all specified folders or folder contents from the system as specified by Adobe in the TechNote.
-- http://kb2.adobe.com/cps/331/331301.html

property scriptVersion : "0.3"
property theScriptDesc : "Adobe Creative Suite 2 Uninstallation Script" & return & ""
property theDate : ""

tell application "Finder"
	activate
	display alert (theScriptDesc as string) message ("Version " & (scriptVersion as string)) giving up after 3 buttons "ï£¿"
	
	-- Delete Folders:
	try
		delete folder "Macintosh HD:Applications:Adobe Acrobat 7.0 Professional:"
		delete folder "Macintosh HD:Applications:Adobe Bridge:"
		delete folder "Macintosh HD:Applications:Adobe GoLive CS2:"
		delete folder "Macintosh HD:Applications:Adobe Illustrator CS2:"
		delete folder "Macintosh HD:Applications:Adobe InDesign CS2:"
		delete folder "Macintosh HD:Applications:Adobe Photoshop CS2:"
		delete folder "Macintosh HD:Applications:Adobe Version Cue CS2:"
		delete folder "Macintosh HD:Applications:Adobe Bridge:"
		delete folder "Macintosh HD:Applications:Adobe:"
		delete folder "Macintosh HD:Library:Application Support:Adobe:"
		delete folder "Macintosh HD:Library:Application Support:Adobe PDF:"
		delete folder "Macintosh HD:Library:Application Support:Adobe Systems:"
		delete folder "Macintosh HD:Library:Preferences:Adobe Systems:"
		delete folder "Macintosh HD:Applications:Utilities:Adobe Utilities:"
		delete folder (path to home folder as Unicode text) & "Documents:AdobeStockPhotos:"
		delete folder (path to home folder as Unicode text) & "Documents:Updater:"
		delete folder (path to home folder as Unicode text) & "Library:Acrobat User Data:"
		delete folder (path to home folder as Unicode text) & "Library:Application Support:Adobe:"
		delete folder (path to home folder as Unicode text) & "Library:Caches:Acrobat:"
		delete folder (path to home folder as Unicode text) & "Library:Caches:Adobe:"
		delete folder (path to home folder as Unicode text) & "Library:Caches:Opera Cache:"
		delete folder (path to home folder as Unicode text) & "Documents:AdobeStockPhotos:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Acrobat:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe GoLive 8.0 Prefs:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe Illustrator CS2 Settings:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe InDesign:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe Photoshop CS2 Paths:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe Photoshop CS2 Settings:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe Save for Web AI 9.0 Prefs:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Adobe Imageready CS2 Settings:"
		delete folder (path to home folder as Unicode text) & "Library:Preferences:Opera Preferences:"
		delete folder (path to home folder as Unicode text) & "Library:Preference Panes:Opera Preferences:"
	end try
	
	-- Delete Files:
	try
		delete file "Macintosh HD:Applications:Adobe Help Center"
		delete file "Macintosh HD:Applications:Adobe Stock Photos"
		delete file "Macintosh HD:Applications:Utilities:Adobe Updater"
		delete file "Macintosh HD:Library:Preferences:com.adobe.acrobat.pdfviewer.plist"
		delete file "Macintosh HD:Library:Preferences:com.Adobe.AdobePDFSettings.plist"
		delete file "Macintosh HD:Library:Preferences:com.adobe.versioncueCS2.plist"
		delete file "Macintosh HD:Library:PreferencePanes:VersionCueCS2.prefPane"
		delete file "Macintosh HD:Library:StartupItems:AdobeVersionCueCS2"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.Acrobat.Pro7.0.plist"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.Acrobat.sh.plist"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.ALM.AdobeLMbundle.plist"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.AMI.Installer.plist"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.Bridge.plist"
		delete file (path to home folder as Unicode text) & "Library:Preferences:Com.Adobe.Photoshop.plist"
		delete file (path to home folder as Unicode text) & "Library:receipts:com.adobe.Acrobat.Pro"
	end try
	
	empty trash
	
end tell


tell application "Finder"
	activate
	display alert ("Adobe Creative Suite 2 Uninstallation Script has completed." as string) giving up after 3 buttons "ï£¿"
end tell

Dylan_Weber · June 23, 2010, 9:39pm

I see what you did, but my hard drive is not called “Macintosh HD.” Just sayin’.

sprale · June 23, 2010, 10:36pm

Yeah, it’s still a bit of a work in progress. I have become more the IT guy and less the Automator in recent months. As for the hard drive name, I just forgot. I make my designers leave certain things alone on the systems I support. I’ll sort that out soon (that’s a lot of lines to update!). Any other criticism or suggestions?

McUsr · June 24, 2010, 9:28am

Hello.

I’m sure Dylan didn’t mean that as a criticism just as a helpful fact.

This little snippet below returns the name of the startup disk where Adobe should naturally reside.


local thNm
tell application "Finder"
	set thNm to name of startup disk
end tell

I you used this and changed this line, you have to do the others.


 delete folder "Macintosh HD:Applications:Adobe Acrobat 7.0 Professional:"

Into something like this:


 delete folder thNm & "Applications:Adobe Acrobat 7.0 Professional:"

On every line where “Machintosh Hd” is represented. (You should be able to do this by some search and replace.

Then your script would run fine on every machine.

I think it is great that you share your code. It must be a real pain in the ass to uninstall Adobe manually.

Best Regards

McUsr

Ray_Barber · June 24, 2010, 9:55am

This applescript also gets the name of the Startup Disk, but without the help from the Finder:

POSIX file "/" as string
--> On my mac: OSX Leopard

Hope it helps,
ief2

StefanK · June 24, 2010, 10:40am

Hi,

there is a problem with the original script.
If en error occurs in the first line, all consecutive lines are skipped.
This is a version which uses relative paths and the rm command to delete the items



-- I've built this script based upon the Adobe TechNote for Creative Suite 2. Adobe has not official uninstaller, nor does the installer perform this function. This script is a bit of a blunt instrument, removing all specified folders or folder contents from the system as specified by Adobe in the TechNote.
-- http://kb2.adobe.com/cps/331/331301.html

property scriptVersion : "0.3"
property theScriptDesc : "Adobe Creative Suite 2 Uninstallation Script" & return & ""
property theDate : ""

set applicationFolder to path to applications folder as text
set applicationSupportFolder to path to application support folder as text
set preferencesFolder to path to preferences folder as text
set utilitiesFolder to path to utilities folder as text
set documentsFolder to path to documents folder as text
set libraryFolder to path to library folder from user domain as text
set mainLibraryFolder to path to library folder as text

tell application "Finder"
	activate
	display alert theScriptDesc message ("Version " & scriptVersion) giving up after 3 buttons "ï£¿"
end tell
-- Delete Folders:

deleteItem(applicationFolder & "Adobe Acrobat 7.0 Professional:")
deleteItem(applicationFolder & "Adobe Bridge:")
deleteItem(applicationFolder & "Adobe GoLive CS2:")
deleteItem(applicationFolder & "Adobe Illustrator CS2:")
deleteItem(applicationFolder & "Adobe InDesign CS2:")
deleteItem(applicationFolder & "Adobe Photoshop CS2:")
deleteItem(applicationFolder & "Adobe Version Cue CS2:")
deleteItem(applicationFolder & "Adobe:")
deleteItem(applicationSupportFolder & "Adobe:")
deleteItem(applicationSupportFolder & "Adobe PDF:")
deleteItem(applicationSupportFolder & "Adobe Systems:")
deleteItem(preferencesFolder & "Adobe Systems:")
deleteItem(utilitiesFolder & "Adobe Utilities:")
deleteItem(documentsFolder & "AdobeStockPhotos:")
deleteItem(documentsFolder & "Updater:")
deleteItem(libraryFolder & "Acrobat User Data:")
deleteItem(libraryFolder & "Application Support:Adobe:")
deleteItem(libraryFolder & "Caches:Acrobat:")
deleteItem(libraryFolder & "Caches:Adobe:")
deleteItem(libraryFolder & "Caches:Opera Cache:")
deleteItem(documentsFolder & "AdobeStockPhotos:")
deleteItem(preferencesFolder & "Acrobat:")
deleteItem(preferencesFolder & "Adobe:")
deleteItem(preferencesFolder & "Adobe GoLive 8.0 Prefs:")
deleteItem(preferencesFolder & "Adobe Illustrator CS2 Settings:")
deleteItem(preferencesFolder & "Adobe InDesign:")
deleteItem(preferencesFolder & "Adobe Photoshop CS2 Paths:")
deleteItem(preferencesFolder & "Adobe Photoshop CS2 Settings:")
deleteItem(preferencesFolder & "Adobe Save for Web AI 9.0 Prefs:")
deleteItem(preferencesFolder & "Adobe Imageready CS2 Settings:")
deleteItem(preferencesFolder & "Opera Preferences:")
deleteItem(libraryFolder & "Preference Panes:Opera Preferences:")

-- Delete Files:

deleteItem(applicationFolder & "Adobe Help Center")
deleteItem(applicationFolder & "Adobe Stock Photos")
deleteItem(utilitiesFolder & "Adobe Updater")
deleteItem(preferencesFolder & "com.adobe.acrobat.pdfviewer.plist")
deleteItem(preferencesFolder & "com.Adobe.AdobePDFSettings.plist")
deleteItem(preferencesFolder & "com.adobe.versioncueCS2.plist")
deleteItem(mainLibraryFolder & "PreferencePanes:VersionCueCS2.prefPane")
deleteItem(mainLibraryFolder & "StartupItems:AdobeVersionCueCS2")
deleteItem(preferencesFolder & "Com.Adobe.Acrobat.Pro7.0.plist")
deleteItem(preferencesFolder & "Com.Adobe.Acrobat.sh.plist")
deleteItem(preferencesFolder & "Com.Adobe.ALM.AdobeLMbundle.plist")
deleteItem(preferencesFolder & "Com.Adobe.AMI.Installer.plist")
deleteItem(preferencesFolder & "Com.Adobe.Bridge.plist")
deleteItem(preferencesFolder & "Com.Adobe.Photoshop.plist")
deleteItem(libraryFolder & "receipts:com.adobe.Acrobat.Pro")

tell application "Finder"
	display alert "Adobe Creative Suite 2 Uninstallation Script has completed." giving up after 3 buttons "ï£¿"
end tell

on deleteItem(f)
	try
		do shell script "/bin/rm -rf " & quoted form of POSIX path of f
	end try
end deleteItem