Another Why one script works and the other doesnt thread?!

Scripting Forums AppleScript | Mac OS X
#1

Ok, this has got me. The first script works perfect. But, I need to make the computer it commands to be variable. So, I inserted a variable format that works for me in every situation…but this, When I use the variable script, I get an error. This only happens when it follows the app “system events”. If I use this network/variable format with any other app, no troubles. Any ideas? I am clueless
works:

tell application "System Events" of machine "eppc://iandopps:dopps1@power"
	if (exists process "iTunes") then
		set status1 to "run"
		tell application "finder" of machine "eppc://iandopps:dopps1@power"
			get quoted form of (text 1 thru -2 of (POSIX path of (path to home folder)))
			do shell script "/usr/bin/find " & result & " -ipath '*iTunes Music*.m4a'"
			set place1 to (first paragraph of result)
		end tell
	end if
end tell
set place2 to POSIX file place1
tell application "System Events" of machine "eppc://iandopps:dopps1@power"
	if (exists process "iTunes") then
		tell application "finder" of machine "eppc://iandopps:dopps1@power"
			open place2
		end tell
	end if
end tell

does not work:

set username to "iandopps" 
set passW to "dopps1" 
set name1 to "power" 
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	if (exists process "iTunes") then
		set status1 to "run"
		tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
			get quoted form of (text 1 thru -2 of (POSIX path of (path to home folder)))
			do shell script "/usr/bin/find " & result & " -ipath '*iTunes Music*.m4a'"
			set place1 to (first paragraph of result)
		end tell
	end if
end tell
set place2 to POSIX file place1
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	if (exists process "iTunes") then
		tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
			open place2
		end tell
	end if
end tell
#2

doc:

I am not sure, but try changing all these:

machine (("eppc://") & username & ":" & passW & "@" & name1)

to this:

machine ((("eppc://") & username & ":" & passW & "@" & name1) as string)

and see if that helps. You may even think about this:

machine ((("eppc://") & username & ":" & passW & "@" & name1) as unicode text)
#3

Hey Craig, I trid those, and no luck. The error I got with my original script is:

“Syntax Error”-"Expected ", " but found ".

and it highlights “iTunes”

i tried this (added "using term from app) . It fixed one problem and made another. Now, it says:

“System Events got an error: Can’t make home folder of application “finder” of machine “eppc://iandopps:dopps1@power” into type constant.”

set username to "iandopps"
set passW to "dopps1"
set name1 to "power"
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	using terms from application "System Events"
		if (exists process "iTunes") then
			set status1 to "run"
			tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
				get quoted form of (text 1 thru -2 of (POSIX path of (path to home folder)))
				do shell script "/usr/bin/find " & result & " -ipath '*iTunes Music*.m4a'"
				set place1 to (first paragraph of result)
			end tell
		end if
	end using terms from
end tell
set place2 to POSIX file place1
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	using terms from application "System Events"
		if (exists process "iTunes") then
			tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
				open place2
			end tell
		end if
	end using terms from
end tell

not sure what this means.

#4

ahh…got it. I needed to add using terms from app “finder” also:

set username to "iandopps"
set passW to "dopps1"
set name1 to "power"
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	using terms from application "System Events"
		if (exists process "iTunes") then
			set status1 to "run"
			tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
				using terms from application "Finder"
					get quoted form of (text 1 thru -2 of (POSIX path of (path to home folder)))
					do shell script "/usr/bin/find " & result & " -ipath '*iTunes Music*.m4a'"
					set place1 to (first paragraph of result)
				end using terms from
			end tell
		end if
	end using terms from
end tell
set place2 to POSIX file place1
tell application "System Events" of machine (("eppc://") & username & ":" & passW & "@" & name1)
	using terms from application "System Events"
		if (exists process "iTunes") then
			tell application "finder" of machine (("eppc://") & username & ":" & passW & "@" & name1)
				using terms from application "Finder"
					open place1
				end using terms from
			end tell
		end if
	end using terms from
end tell