applescript quicktime multiple selecions

Scripting Forums AppleScript | Mac OS X
#1

hi, I’m new on this forum.
I’m working on a script for export an image sequence in a quicktime movie
I need to select a numbers of folders and create the sequence starting from the first file of each folder
I have some problem because of some errors like ‘finder doesn’t understand the command open image sequence’.

this is the code I’m writing:


theFolders to choose folder with prompt "Export these image squences to video files:" with multiple selections allowed without invisibles
tell application "Finder" to repeat with oneFolder in theFolders
	try
		tell application "Finder" to set this_file to first file of folder oneFolder
		tell application "QuickTime Player"
			activate
			open image sequence this_file
			set nomevero to this_file
			tell application "Finder"
				set thePath to oneFolder as string
				
				set lunghezza to ((length of nomevero) - 4)
				set newName to (get text 1 through lunghezza of nomevero) & ".mov"
				
			end tell
			
			export front document to (thePath & newName) as QuickTime movie using most recent settings
			close front document saving no
		end tell
	on error error_message
		display dialog error_message
	end try
end repeat

please, can you help me?

thank you
lorenzo.

#2

Ciao Lorenzo e benvenuto su MacScripter.

open image sequence expects a file or an alias, but not the class file of the Finder
Try this version, I made some other corections :wink:

set theFolders to choose folder with prompt "Export these image squences to video files:" with multiple selections allowed without invisibles
repeat with oneFolder in theFolders
	try
		tell application "Finder" to set this_file to first file of folder oneFolder as alias
		tell application "QuickTime Player"
			activate
			open image sequence this_file
			set nomevero to name of (info for this_file)
			set thePath to oneFolder as Unicode text
			set lunghezza to ((length of nomevero) - 4)
			set newName to (get text 1 through lunghezza of nomevero) & ".mov"
			export front document to (thePath & newName) as QuickTime movie using most recent settings
			close front document saving no
		end tell
	on error error_message
		display dialog error_message
	end try
end repeat