Checking if property is "missing value" not working

Scripting Forums AppleScript | Mac OS X
,
#1

I would like to understand why I cannot check if a dedicated property is ‘missing value’ without casting all properties to a variable. Here are two examples where the latter that works great.
R�diger

 
Example that does NOT work: 
tell application "Address Book" 
        set the_people to every person 
        set the_images to {} 

   repeat with i from 1 to number of items in the_people 
                set this_item to item i of the_people 
                try 
                        set this_image to (image of this_item) 
                end try 
                if this_image is not missing value then 
                        set the_images to the_images & name of this_item 
                end if 
        end repeat 
end tell 


Example that does work: 
tell application "Address Book" 
        set the_people to every person 
        set the_images to {} 

   repeat with i from 1 to number of items in the_people 
                set this_item to item i of the_people 
                set this_properties to properties of this_item 
                try 
                        set this_image to (image of this_properties) 
                end try 
                if this_image is not missing value then 
                        set the_images to the_images & name of this_properties 
                end if 
        end repeat 
end tell
#2

“missing value” IS something that exists. A value (err… well, a “missing” value).
But if such image doesn’t exist, AB won’t return “missing value”. You could use also (a bit more quick):

tell application "Address Book"
	set the_people to every person
	set the_images to {}
	set tmp_list to {}
	
	repeat with i from 1 to count the_people
		set tmp_list's end to image of the_people's item i
		if (class of tmp_list's item -1) = TIFF picture then ¬
			set the_images's end to name of the_people's item i
	end repeat
end tell
#3

Or, faster:

tell application "Address Book"
	set pNames to name of every person
	set pImages to image of every person
end tell
set theList to {}
repeat with i from 1 to count pNames
	if pImages's item i is not missing value then ¬
		set theList's end to pNames's item i
end repeat
theList

(I know this doesn’t answer your question. Sorry.)