Choose file and then Return "path to folder"

Scripting Forums AppleScript | Mac OS X
, ,
#1

hi there,

I would like (love!) to get to solution for this one:


set this_file to choose file
-- Result looks like: "Mac OS X:Users:myusername:Desktop:Somefolder:thefile sometime-with-spaces.xml"

But i do not need the filename (in this example thefile sometime-with-spaces.xml) in only need the
“Mac OS X:Users:myusername:Desktop:somefolder:” part.

I do not want to use the “choose folder” because then users need to choose twice…

Hope someone can help me out here!

Thanks,

Steven

#2

Either of these should work:

choose file without invisibles
set theFile to result as Unicode text

set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {":"}
set theFolder to (text items 1 thru -2 of theFile) & "" as Unicode text
set AppleScript's text item delimiters to ASTID

return theFolder


choose file without invisibles
set theFile to result

tell application "Finder" to set theFolder to container of theFile as Unicode text
#3

steven:

Here’s a little one-liner…


tell application "Finder" to set filePath to ((container of (choose file with prompt "choose a file...")) as string)

You might want to split it up if you’re doing other Finder ops and take out the “as string” depending on your purpose for the query.

Have Fun,
Jim Neumann
BLUEFROG

#4

Bruce / Jim,

Thanks for the feedback! I’am using Bruce’ first script! Works great.

Thanks again,

Steven

#5

This is in System Events. You don’t need the Finder at all:

tell application "System Events" to set parentLocationAsAlias to (path of (container of childObject))
#6

Hi, Bruce. I hope you won’t mind me being finicky and pointing out that a more efficient action here would be:

set theFolder to (text 1 thru text item -2 of theFile) & ":"

This doesn’t involve any list work and is thus about three times as fast.

#7

And what’s interesting too is that Nigel’s modified form of Bruce’s script is just over 15 times faster than invoking System Events to get the container in my test (as follows):

choose file without invisibles
set theFile to result as Unicode text
set t1 to GetMilliSec
repeat 100 times
	set ASTID to AppleScript's text item delimiters
	set AppleScript's text item delimiters to {":"}
	set theFolder to (text 1 thru text item -2 of theFile) & ":" as Unicode text
	set AppleScript's text item delimiters to ASTID
end repeat
set t2 to GetMilliSec
(t2 - t1) / 100

vs:

choose file without invisibles
set theFile to result
set t1 to GetMilliSec
repeat 100 times
	tell application "System Events" to set theFolder to path of container of theFile as Unicode text
end repeat
set t2 to GetMilliSec
(t2 - t1) / 100
#8

It’s a fast method. :slight_smile:

Apart from the ‘choose file’ command, which is in the StandardAdditions OSAX, Bruce’s script is pure, vanilla AppleScript and the action’s a simple text manipulation that’s handled by AppleScript itself. System Events and the Finder, on the other hand, are both external applications, so control has to be passed to and fro between them and the script. They also have to do a little work to recognise commands and analyse references that arrive. I don’t know how they ascertain the container of a file, but I suspect it’s not just by manipulating text…

#9

Not at all Nigel. Actually, I recall figuring that one out not too long ago. I haven’t been feeling well lately, so it must have slipped my mind. Regardless, thanks for the input.

#10

I suppose I should also have noted that if there’s any danger that ‘theFile’ might refer to a package, an allowance will have to be made for the colon at the end:

choose file without invisibles
set theFile to result as Unicode text

if (theFile ends with ":") then
	set c to -3
else
	set c to -2
end if
set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {":"}
set theFolder to text 1 thru text item c of theFile & ":"
set AppleScript's text item delimiters to ASTID

return theFolder

I’m sorry to hear that. I hope you’re soon recovered. :slight_smile: