Convert Number Ranges to Individual Numbers

[peavine]

I wrote a shortcut that converts a string containing individual numbers and ranges of numbers to individual numbers only. My first effort used two loops and took 120 milliseconds to run.

Create Numbers One.shortcut (23.1 KB)

My second effort used one loop but required a string containing consecutive numbers that exceed the highest number in the string being processed. This took 75 milliseconds to run.

Create Numbers.shortcut (23.2 KB)

I know it’s unlikely, but I wondered if anyone knew a shortcut solution that’s simpler or faster.

[StefanK]

Just for fun, this is the AppleScriptObjC version using NSMutableIndexSet and NSRange.
The ranges {location, length} are represented by 1st item and (2nd item + 1) - 1st item

use AppleScript version "2.5"
use framework "Foundation"
use scripting additions

-- a trick to handle NSNotFound properly. Credits: https://latenightsw.com/high-sierra-applescriptobjc-bugs/
property NSNotFound : a reference to 9.22337203685477E+18 + 5807

set theText to "1 3-6 8 10-13 15 17-20"
set indexSet to current application's NSMutableIndexSet's new()
set {saveTID, text item delimiters} to {text item delimiters, {space}}
set theParts to text items of theText
set text item delimiters to {"-"}
repeat with aPart in theParts
	set theRange to text items of aPart
	if (count theRange) is 1 then
		(indexSet's addIndex:(item 1 of theRange as integer))
	else
		set theLocation to item 1 of theRange as integer
		set theLength to ((item 2 of theRange as integer) + 1) - theLocation
		(indexSet's addIndexesInRange:({theLocation, theLength}))
	end if
end repeat
set resultArray to {}
repeat until indexSet's firstIndex() = NSNotFound
	set end of resultArray to indexSet's firstIndex()
	indexSet's removeIndex:(indexSet's firstIndex())
end repeat
set text item delimiters to {space}
display dialog (resultArray as text)
set text item delimiters to saveTID

[peavine]

Here’s a solution that uses the shell seq command. This took 125 milliseconds to run, although this solution might be a good one if the number of pages in the page ranges is large. Also, it is reasonably short.

Create Numbers Shell.shortcut (22.8 KB)

[Nigel_Garvey]

@StefanK

The ranges {location, length} are represented by 1st item and 2nd item - 1st item

Hi @StefanK

I think the range length should be 2nd item - 1st item + 1, otherwise the second item’s omitted from the run.

Here’s a vanilla handler I wrote a couple of years ago. It handles negatives as well as positives and accepts either commas or spaces as separators, but as it stands, it can’t cope with multiple separators between number groups:

on rangeExpansion(rangeExpression)
	-- Split the expression at the commas, if any.
	set astid to AppleScript's text item delimiters
	set AppleScript's text item delimiters to {",", space}
	set theRanges to rangeExpression's text items
	
	set integerList to {}
	set AppleScript's text item delimiters to "-"
	repeat with thisRange in theRanges
		-- Split each range or integer text at its dash(es), if any.
		set rangeParts to thisRange's text items
		-- If the first text item's "", the first integer was preceded by a minus sign, so insert the negative of the SECOND text item at the beginning of the parts list.
		if (rangeParts begins with "") then set beginning of rangeParts to -(item 2 of rangeParts)
		-- Similarly, if the penultimate text item's "", insert the negative of the last text item at the end of the parts list.        
		if (((count rangeParts) > 1) and (item -2 of rangeParts is "")) then set end of rangeParts to -(end of rangeParts)
		-- Append all the integers implied by the range to the output list.
		repeat with i from (beginning of rangeParts) to (end of rangeParts)
			set end of integerList to i
		end repeat
	end repeat
	set AppleScript's text item delimiters to astid
	
	return integerList
end rangeExpansion

-- Demo code:
set rangeExpression to "-6,-3--1,3-5,7-11,14,15,17-20"
-- set rangeExpression to "1 3-6 8 10-13 15 17-20"

return rangeExpansion(rangeExpression)
--> {-6, -3, -2, -1, 3, 4, 5, 7, 8, 9, 10, 11, 14, 15, 17, 18, 19, 20}

[StefanK]

@Nigel_Garvey

I think the range length should be 2nd item - 1st item + 1, otherwise the second item’s omitted from the run.

Right, thanks, good catch.

[technomorph]

@StefanK

repeat until indexSet's firstIndex() = NSNotFound

Too bad can’t use:

• (void) enumerateIndexesUsingBlock

In my own personal helper framework I have a category on NSIndexset

-(NSArray*)indexSetAsArray;
-(NSMutableArray*)indexSetAsMutableArray;

And on NSArray

-(NSIndexSet*)arrayAsIndexSet;
-(NSMutableIndexSet*)arrayAsMutableIndexSet;

[StefanK]

@technomorph

In my own personal helper framework…

…I would use Swift where you can create an array from an IndexSet just with

let allIndices = Array(indexSet)

[Nigel_Garvey]

At the risk of being complicit in the hijacking of peavine’s Shortcuts topic , I’d like to point out that the range setting code in Stefan’s first repeat can, with a minor tweak, be made to serve the single-item situation too:

repeat with aPart in theParts
	set theRange to text items of aPart
	set theLocation to item 1 of theRange as integer
	set theLength to ((item -1 of theRange) + 1) - theLocation
	(indexSet's addIndexesInRange:({theLocation, theLength}))
end repeat

And in the second repeat, it’s possible both to reduce the number of reads of indexSet's firstIndex() and to dispense with the NSNotFound trick by simply iterating the same number of times as there are indices in the set:

repeat (indexSet's |count|()) times
	set anIndex to indexSet's firstIndex()
	set end of resultArray to anIndex
	indexSet's removeIndex:(anIndex)
end repeat

Slightly more longwindedly, it’s possible to extract the indices without reducing the set. But I don’t know if this is more efficient or not:

set indexCount to indexSet's |count|()
if (indexCount > 0) then
	set anIndex to (indexSet's firstIndex()) - 1
	repeat indexCount times
		set anIndex to indexSet's indexGreaterThanIndex:(anIndex)
		set end of resultArray to anIndex
	end repeat
end if

[peavine]

@Nigel_Garvey

At the risk of being complicit in the hijacking of peavine’s Shortcuts topic…

Nigel. On many occasions I have posted a shortcut solution in an AppleScript thread, so no complaints from me.

I wrote a slightly different version of my shortcut that uses the shell. With my original string input, the timing result for this shortcut was 110 milliseconds. After modifying the string input to include a very-large page range, the timing result was 115 milliseconds (excluding the Show Result action).

Create Numbers with Shell.shortcut (22.7 KB)

[VikingOSX]

In Swift 6:

/*
    expRange.swift

    xcrun --sdk macosx swiftc -Osize expRange.swift

    Usage: expRange 1,3-7,10-20,24
    Result: 1 3 4 5 6 7 10 11 12 13 14 15 16 17 18 19 20 24
*/
import Foundation

extension String {
    var isNumber : Bool {
        return !isEmpty && rangeOfCharacter(from: CharacterSet.decimalDigits.inverted) == nil
    }
    var isRange : Bool {
        var thisSet = CharacterSet()
        thisSet.insert(charactersIn: "0123456780-")
        // return self.rangeOfCharacter(from: thisSet) != nil
        return CharacterSet(charactersIn: self).isSubset(of: thisSet)
    }
    // return sequential string of white-space separated numbers including expanded ranges
    func expand() -> String {
        let sa = self.split(whereSeparator: { $0 == ","}).filter({ !$0.isEmpty })
        var t = ""
        for n in sa {
            if !n.contains("-") {
                guard String(n).isNumber else { continue }
               t += n + " "
            } else {
                guard String(n).isRange else { continue }
                let na = n.split(separator: "-").map { Int($0)! }
                t += stride(from:na[0], through:na[1], by:1).compactMap { String($0)}.joined(separator: " ") + " "
            }
        }
        return t
    }
}

let args = CommandLine.arguments[1] as String
print(args.expand())

in Snobol4:

#!/usr/bin/env snobol4

*       # Return range n1 .. n2        
        define('range(n1,n2)') :(range_end)
range   range = range n1 ','; n1 = lt(n1,n2) n1 + 1 :s(range)
        range rtab(1) . range :(return)
range_end        

        define('rangex(range)d1,d2') 
        num = ('-' | '') span('0123456789') :(rangex_end)
rangex  range num . d1 '-' num . d2 = range(d1,d2) :s(rangex)
        rangex = range :(return)
rangex_end

*       # Test and display        
        output = rangex('-6,-3--1,3-5,7-11,14,15,17-20')
        output = rangex(input)
end

expRange.sno
-6,-3,-2,-1,3,4,5,7,8,9,10,11,14,15,17,18,19,20

in Zsh shell:

#!/bin/zsh

: <<"COMMENT"

Usage: exp.zsh 1-3,4,5,7-10,12,15-20

COMMENT

typeset -a items=()
RANGE="$1"

# split the expansion string by commas into an array
items=( ${(s:,:)RANGE} )

# allows for sequential expansion of {n..m} sequences
setopt BRACE_CCL


for n in $items;
do
    # check if n is just a number and not n-m
    [[ $n =~ "^([0-9]+)$" ]] && outseq+="$n " && continue
        # expand {n..m}
        outseq+="$(print {${${n}:gs/-/..}}) "
done

print $outseq
unset items outseq
exit 0

in Perl:

#!/usr/bin/env perl

# expand sequence of numbers (e.g. 1-10,11,12,13-20)
# reference: https://rosettacode.org/wiki/Range_expansion#Perl

sub rangex {
    map { /^(.*\d)-(.+)$/ ? $1..$2 : $_ } split /,/, shift
}

print join(' ', rangex($ARGV[0])), "\n";