I’ve taken the liberty of editing your script, hope you don’t mind. 
There were many little things. First one was like Stefan said. Then I changed the try…error block to be a bit more extensive and display the error number too.
Then there was the problem of the name of the file. You tried to force the duplicate’s name to change to a new name with a JPG extension although the file is most probably not in that format. You should do this when you save the file at the end, when you are certain that the file is actually a JPEG. And also you tried to save the file to a path that only defined it’s name, no path to this file.
There was also a few other enhancements to simplify the readability of the script and some changes to help Image Events receive things as it wants them. Let us know if this helps.
There is as few lines that are commented out, they were for debugging purposes, i.e., they’re useless.
property saveTypes : {"BMP", "JPEG", "JPEG2", "PICT", "PNG", "PSD", "TIFF"}
property openTypes : {"PDF", "com.adobe.pdf", "BMP", "com.microsoft.bmp", "JPEG", "JPEG2", "jpg", "public.jpeg", "PICT", "com.apple.pict", "PNG", "public.png", "PSD", "com.adobe.photoshop-image", "TIFF", "public.tiff"}
--Get the artwork file
set sourceFile to choose file with prompt "Choose art file(s)" of type openTypes without multiple selections allowed and invisibles
tell application "Finder"
try
set errorOccured to false
set pathToAppSupportInUserDomain to (path to application support as string)
set pathToSaveNewFiles to (path to desktop folder as string)
set nameOfTempFolder to "FILEPROCESSING"
set nameOfProcessedFilesFolder to "FILES_PROCESSED"
try
tell application "Finder" to make new folder in container (path to application support) with properties {name:nameOfTempFolder}
end try
try
tell application "Finder" to make new folder in container (path to desktop folder) with properties {name:nameOfProcessedFilesFolder}
end try
set tempDestinationFolder to (pathToAppSupportInUserDomain & nameOfTempFolder & ":") as string
set processedFilesDestinationFolder to (pathToSaveNewFiles & nameOfProcessedFilesFolder & ":") as string
--tell application "Finder" to open tempDestinationFolder
--display dialog tempDestinationFolder as string
set theDuplicateFile to duplicate file sourceFile to tempDestinationFolder as alias
set theDuplicateFileAsPosix to quoted form of (POSIX path of (theDuplicateFile as string))
do shell script ("/usr/bin/sips -m '/System/Library/ColorSync/Profiles/Generic RGB Profile.icc' " & theDuplicateFileAsPosix)
set theDuplicateFileExtension to name extension of theDuplicateFile
set newFileName to ((text 1 thru -((count of characters in theDuplicateFileExtension) + 1) of (get name of theDuplicateFile)) & "JPG")
--display dialog newFileName
on error theError number theErrorNumber
set errorOccured to true
try
tell application "Finder" to delete file (theDuplicateFile as alias)
end try
tell application "Finder" to display alert "Error!" message ((theErrorNumber & " : " & theError) as string) buttons {"OK"} default button "OK"
end try
end tell
if errorOccured is false then
tell application "Image Events"
try
launch
set imageFile to open (theDuplicateFile as string)
set theSize to dimensions of imageFile
set {imageWidth, imageHeight} to {item 1 of theSize, item 2 of theSize}
set imageRatio to (imageWidth / imageHeight)
set newHeight to 1024
set newWidth to (imageRatio * newHeight) as integer
if newHeight > newWidth then
tell imageFile to scale to size newHeight
else
tell imageFile to scale to size newWidth
end if
tell imageFile to save as JPEG in (processedFilesDestinationFolder & newFileName)
on error theError number theErrorNumber
set errorOccured to true
try
close imageFile
tell application "Finder" to delete file (theDuplicateFile as alias)
end try
tell application "Finder" to display alert "Error!" message ((theErrorNumber & " : " & theError) as string) buttons {"OK"} default button "OK"
end try
end tell
if errorOccured is false then display dialog "Wrote " & newFileName giving up after 1
try
close imageFile
tell application "Finder" to delete file (theDuplicateFile as alias)
end try
end if
Model: MacBookPro8,2
Browser: Safari 534.51.22
Operating System: Mac OS X (10.7)