I am looking for a script that can do the following:
Asks the operator what file i want to convert.
Once they choose it will saving it as the name the operator chooses
It will save the pdf(ps) to a folder on a network drive
Anyone have any ideas?
I also have a few more questions:
Am i able to add the mimimise, maximise and close radio buttons to the toolbar of a script ive written?
When i set up a item list, underneath there are 2 buttons, cancel and ok, am i able to remove those?
and last one
Am i able to embed an image in an applescript app? so if i press a button it brings up a pic of darth vader on any machine that the script is being run
This is how I save qxp files as PDFs from Quark.
You will have to have Acrobat Distiller watching a folder on your desktop called “DISTILLER_WATCHFOLDER”. (Otherwise the following script will save a .ps file, which I guess you could always open with ‘Preview’)
set theQ to (choose file with prompt "Select your QXP doc")
set nameOnly to do shell script "echo " & theQ & " | rev | cut -d':' -f1 | rev | cut -d'.' -f1"
set theOutputFolder to (((path to desktop folder) as string) & "DISTILLER_WATCHFOLDER:In:")
tell application "QuarkXPress"
open theQ
--(*
tell document 1
tell print setup -- Define as much as possible
set printer type to "DocuColor 240 PS"
set paper size to "SRA3 SEF"
--set paper height to 320
--set paper width to 460
set orientation to landscape
set page position to center position
set print spreads to false
set fit in area to false
set reduce or enlarge to 100
set registration marks to centered
set halftone screen to 150.0 -- force halftones to 150lpi
set full res rotated objects to true
set print quality to normal
set registration marks offset to 8.504 -- - 3mm as points
set resolution to 300 -- force resolution to 300dpi
set separation to false -- print as composite!
set output setup to "Composite CMYK"
end tell
tell custom bleeds setup 1
set bleed type to asymmetric
set bleed to {"3mm", "3mm", "3mm", "3mm"}
set bleed clipping to false
end tell
set thePostscriptFilePath to theOutputFolder
set psName to nameOnly & ".ps"
print (page 1) PostScript file thePostscriptFilePath & psName
end tell
-- *)
end tell
The first part (before the tell Quark block) asks the user to select a file, gets the name of that file, dropping the .qxp, then defines where to save the file.
If you wanted to change the name of the output .ps file, you could change the
set nameOnly to do shell script "echo " & theQ & " | rev | cut -d':' -f1 | rev | cut -d'.' -f1"
to
set nameOnly to text returned of (display dialog "What will you save me as?" default answer "Output")
Within the Quark tell block, you have to tell ‘print setup’ to set printer specific settings relative to your printer. Here I am using a Xerox Docucolor. Most of these are self explanatory and for specific settings (such as paper size) these can be found when you go to print a page from Quark and select the relevant printer and print driver.
You also have to define ‘custom bleeds setup’ before finally printing to a postscript file.
