Create a new table in inDesign

Scripting Forums AppleScript | Mac OS X
#1

Hi guys,

i’m trying to make a new table in InDesign with this script


tell application "Adobe InDesign CS4"
	set myDoc to active document
	set myRegColor to swatch "Registration" of myDoc
	set myContent to {"This", "is", "a", "simple", "table", "script"}
	tell myDoc
		set myTextFrame to make text frame with properties {geometric bounds:{0, 0, 0.375, 2.5}, fill color:"None", fill tint:100, stroke color:myRegColor, stroke tint:100, stroke weight:0.15, stroke alignment:outside alignment}
		set myTable to make new table in myTextFrame with properties {height:0.375, column count:2, width:2.5, body row count:3, contents:myContent}
		set properties of cells of myTable to {height:0.125, width:1.25, bottom edge stroke color:"None", bottom edge stroke weight:0, inner column stroke color:myRegColor, inner column stroke weight:0.15, left edge stroke color:"None", left edge stroke weight:0, right edge stroke color:"None", right edge stroke weight:0, top edge stroke color:"None", top edge stroke weight:0, top inset:0, vertical justification:center align, inner row stroke color:myRegColor, inner row stroke weight:0.15, left inset:0, right inset:0, bottom inset:0}
	end tell
end tell

My problem is that my inner column and inner row strokes are still invisible even if i tell them not to be in the cell’s properties.

Can you help me please???

#2

Hi. I’m using CS”not CS4”so this may or may not apply to your version, but, it doesn’t work as expected. The cell object is unresponsive to inner anything, however, targeting a column allows you to set the inner row stroke and targeting a row allows you to set the inner column stroke. There appears to be a bug either in the documentation or functionality.

#3

Thanks,

Here’s how i fixed the problem.


tell application "Adobe InDesign CS4"
	set myDoc to active document
	set myRegColor to swatch "Registration" of myDoc
	set myContent to {"This", "is", "a", "simple", "table", "script"}
	tell myDoc
		set myTextFrame to make text frame with properties {geometric bounds:{0, 0, 0.375, 2.5}, fill color:"None", fill tint:100, stroke color:myRegColor, stroke tint:100, stroke weight:0.15, stroke alignment:outside alignment}
		set myTable to make new table in myTextFrame with properties {height:0.375, column count:2, width:2.5, body row count:3, contents:myContent}
		set properties of columns of myTable to {height:0.125, width:1.25, bottom edge stroke color:"None", bottom edge stroke weight:0, inner column stroke color:myRegColor, inner column stroke weight:0.15, left edge stroke color:"None", left edge stroke weight:0, right edge stroke color:"None", right edge stroke weight:0, top edge stroke color:"None", top edge stroke weight:0, top inset:0, vertical justification:center align, inner row stroke color:myRegColor, inner row stroke weight:0.15, left inset:0, right inset:0, bottom inset:0}
		set properties of rows of myTable to {inner column stroke color:myRegColor, inner column stroke weight:0.15, auto grow:false}
	end tell
end tell