Create new client folder with subfolders good for prepress

Scripting Forums AppleScript | Mac OS X
,
#1

Useful script for prepress below, One enhancement im after is to have an error message or something when inputing client name and characters are more than 16.

property subf_names : {"LB Artwork", "Supplied Artwork", "PDF Proofs", "Fonts", "Print Files"}
property subfff_names : {"_Col T", "_Inca", "_Vutek", "_CutV", "_HP Gr", "_Chief"} -- change these folder names relevent to your work

--
display dialog "Enter Client name:" default answer "Client name (max of 16 characters)"
set j_name to text returned of result
repeat
	display dialog "Enter job number:" default answer "AA0000"
	set j_number to text returned of result
	exit repeat
end repeat
set job_number to text -9 thru -1 of ("0000" & j_number & "_") -- change 9 higher or lower for amount of characters
set temp_name to job_number & j_name
tell application "Finder"
	set main_folder to (make new folder at "Macintosh HD:Users:trigger:Desktop:JW WORK new" with properties {name:temp_name}) as alias
	repeat with this_name in subf_names
		set temp_name to this_name
		set subFolder to make new folder at main_folder with properties {name:temp_name} --> line changed: the last folder in the list must be "Print Files"
	end repeat
	
	repeat with this_name in subfff_names
		set temp_name to job_number & j_name & this_name
		make new folder at subFolder with properties {name:temp_name} -- line changed
	end repeat
	open "Macintosh HD:Users:trigger:Desktop:JW WORK new" -- change this to main folder to bring new folder to front
	set current view of Finder window 1 to list view
	set position of Finder window 1 to {200, 200}
	
end tell
#2

Something like this:

set D1 to "Client Name (max of 16 characters)"
set D2 to "Client Name must be fewer than 16 characters, including spaces!"
set D to D1
repeat
	set j_name to text returned of (display dialog D default answer "Client Name")
	if (count j_name) > 16 then
		set D to D2
	else
		exit repeat
	end if
end repeat
#3

Cheers, perfect thanks
JW