create shortcuts of a folder on desktop

Scripting Forums AppleScript | Mac OS X
#1

This is what I have so far, but not yet working? Any Help Please?
Thanks
Matt

set dtF to paragraphs of (do shell script "ls -F /Volumes/Scratches/Workings | grep '/' | cut -d'/' -f1")
set tc to (count dtF)
repeat with i from 1 to tc
	set folderName to item i of dtF
	tell application "Finder" to make new alias at (path to desktop folder) to folder folderName
end repeat

Browser: Safari 534.57.2
Operating System: Mac OS X (10.8)

#2

Hi,

The issues why the script fails are:
¢ The Finder accepts only HFS paths (colon separated)
¢ The variable folderName must contain the full (HFS) path to the folder
¢ A Finder alias is called alias file in AppleScript


set baseFolderPath to "Scratches:Workings:"
set dtF to paragraphs of (do shell script "ls -F " & quoted form of POSIX path of baseFolderPath & " | grep '/' | cut -d'/' -f1")
repeat with aFolder in dtF
	tell application "Finder" to make new alias file at desktop to folder (baseFolderPath & aFolder)
end repeat
#3

NICE! Thanks again, how can I wipe the desktop clean of alias, as I would run this applescript on boot?

Matt

#4 

tell application "Finder" to delete every alias file of desktop

PS: This is a version of your script without the shell


tell application "Finder"
	set allFolders to folders of folder "Scratches:Workings:"
	repeat with aFolder in allFolders
		make new alias file at desktop to aFolder
	end repeat
end tell

or still shorter


tell application "Finder" to make new alias file at desktop to folders of folder "Scratches:Workings:"
#5

That looks better. I can understand that more, I’m recycling scripts so I though the shell was a good option.

thanks
Again