I have about 35 gigs of music on my desktop. I know nothing about scripts, and for that Im sorry. What I would like to know is this:
Is it possible to somehow run a script that would go through my entire music library…copy each folders artist name…go into iTunes create a playlist…name the playlist…copy the songs to the playlist…go back to the music library and repeat the process until its all said and done? Does such a script already exist? Is it not possible? Could an extreme script novice such as myself even write such a script w/ no experience? Or would I need alot of practice first? Sorry to be such a newbeeee.
I think this is what you want (there are probably better ways of doing this). This assumes that the first level of folders in your music folder are the artist names which are used for the playlist names. All music files contained within those folders (as designated by the music type extensions at the top of the script) will be added to the artist playlist. This should be fairly quick (a minute or two per 1,000 files on a reasonably modern machine):
set music_types to {"mp3", "m4p", "m4a", "aiff"}
set itunes_folder to ((path to "cusr" as string) & "Music:iTunes:iTunes Music:") --set this to your iTunes Music folder
tell application "System Events" to set the_artists to name of folders of folder itunes_folder
repeat with this_artist in the_artists
set this_artist to contents of this_artist
set the_files_posix to {}
repeat with this_music_type in music_types
set new_files to (do shell script "find " & (quoted form of POSIX path of (itunes_folder & this_artist)) & " -iname '*" & this_music_type & "' -print")
if new_files is not "" then set the_files_posix to the_files_posix & (paragraphs of new_files)
end repeat
set the_files to {}
repeat with this_file in the_files_posix
set end of the_files to ((text 2 thru -1 of (POSIX path of this_file)) as alias)
end repeat
my add_files_to_playlist(this_artist, the_files)
end repeat
on add_files_to_playlist(target_playlist, the_files)
tell application "iTunes"
if (exists of playlist target_playlist) = false then make new playlist with properties {name:target_playlist}
add the_files to playlist target_playlist
end tell
end add_files_to_playlist
Jon
Looks great! I will let you know how it worked when I get around to putting it to use tommorow.