Creating Folders From Excel from multiple columns and subfolders

Scripting Forums AppleScript | Mac OS X
#1

Hello all, I have searched and tried more complex strings of code mish mashed from multiple threads but have had no luck. Any help at all is appreciated!

I want to create a series of folders named as “event number_event name_year_month & day” For example: “44382_Coney Island_2013_0302”

These values will be pulled from four excel columns with underscores added by the script. Inside each folder it creates I want end up with two subfolders: “JPG” and “RAW”

Hoping to learn a bit more about referencing multiple columns etc. along the way! THANK YOU SO MUCH FOR ANY HELP!

The most basic code I got to work was from a single column and was this:

set destinationFolder to "Macintosh HD:Users:cwray:Desktop:Folders"

tell application "Microsoft Excel"
	set theCells to value of range "A1:A9" of active sheet
end tell
repeat with oneCell in theCells
	tell application "Finder" to make new folder at folder destinationFolder with properties {name:item 1 of oneCell}
end repeat

Model: imac
AppleScript: Version 2.4.3 (131.2)
Browser: Safari 537.22
Operating System: Mac OS X (10.7)

#2

Hi,

try this, it expects event number, event name, year, month and day in columns A to E


set destinationFolder to (path to desktop as text) & "Folders"

tell application "Microsoft Excel"
	set theRows to string value of used range of active sheet
end tell
set {TID, text item delimiters} to {text item delimiters, "_"}
repeat with oneRow in theRows
	set {eventNumber, eventName, theYear, theMonth, theDay} to items of oneRow
	set folderName to ({eventNumber, eventName, theYear, theMonth} as text) & theDay
	
	tell application "Finder"
		set projectFolder to make new folder at folder destinationFolder with properties {name:folderName}
		make new folder at projectFolder with properties {name:"RAW"}
		make new folder at projectFolder with properties {name:"JPG"}
	end tell
end repeat
set text item delimiters to TID
#3

Best morning ever, it’s mind boggling how simple the script is. So appreciate you can’t even imagine!