Export from Address Book?

[benreilly]

Is it possible to export groups from Address Book?

Don’t want to do anything too difficut just export a group(s) from address book as a vCard.

Can anyone help?

[jonn8]

This will allow you to choose a group and then export all of the cards from that group as individual vcards:

–Open this script in a new Script Editor window.

set target_folder to (choose folder with prompt “Choose a folder for the VCards:”) as Unicode text

tell application “Address Book” to set all_groups to name of groups
set this_group to (choose from list all_groups with prompt “Which group do you want to export?” OK button name “Export”) as Unicode text
if this_group = “false” then return

tell application “Address Book”
repeat with this_person in people
if (get this_person’s groups’s name) contains this_group then my write_to_file((target_folder & (this_person’s name) & “.vcf”), (this_person’s vcard), “”, “”)
end repeat
end tell

on write_to_file(the_file, the_data, creator_code, file_type)
try
set f to open for access file the_file with write permission
write the_data to f starting at eof as (class of the_data)
close access f
try
tell application “System Events”
if creator_code is not missing value then set creator type of (file the_file) to creator_code
if file_type is not missing value then set file type of (file the_file) to file_type
end tell
end try
return true
on error the_error
try
close access file the_file
end try
return the_error
end try
end write_to_file

For saving all of the contacts as a single vcard, you don’t really need a script:

http://www.macworld.com/weblogs/mac911/2005/02/singlevcards/index.php

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]

[benreilly]

Thanks for the reply. I need to export the group as a single vCard. I’m going to be running the script via Pod2Go at set times.

I had a reply on the Apple Discusions:

set PathName to (choose folder)
tell application "Address Book"
	set GroupName to item 1 of (choose from list (get (name of groups)))
	if GroupName is not false then
		set myGroup to vcard of people of group GroupName
		set vcardinfo to myGroup as string
		my makeExportFile(PathName, GroupName, vcardinfo)
	end if
end tell

on makeExportFile(PathName, GroupName, vcardinfo)
	try
		set target_name to GroupName & ".vcf"
		set target_file to (PathName as text) & target_name
		tell application "Finder" to make new file at PathName ¬
			with properties {name:GroupName & ".vcf", creator type:"adrb"}
		set the open_target_file to ¬
			open for access file target_file with write permission
		set eof of the open_target_file to 0
		write vcardinfo to the open_target_file starting at eof
		close access the open_target_file
	on error theErrMsg number theErrNumber
		return theErrNumber
	end try
end makeExportFile

So between the Script you have supplied and this one I think I’ll have my script sorted.

Thanks for the reply
Ben.