Find special folder and put part of name in clipboard

Scripting Forums AppleScript | Mac OS X
,
#1

On my desktop I have (only) one folder which name starts with the word
�Proofs� (the rest of the name will always be different). I need to build an
Applescript that finds that folder and copies its name to the clipboard BUT
only the part without the word �Proofs�. For instance I could have a folder
called �ProofsLinda&Jason600PYDVD�. So the script should copy
�Linda&Jason600PYDVD� to the clipboard.

If this was not complicated enough, the script now need to make a decision
based on the last letters. There are 8 possible combinations jumping to 4
possible places in the script (or triggering 4 independent scripts):
PYDVD
PNDVD
OYDVD
ONDVD
PYCD
PNCD
OYCD
ONCD

So if the name (stored in the clipboard) contains �PYDVD� jump to script
step �soandso�, if the name contains �PYCD� jump to the same place.

If the name contains �PNDVD� jump to script step �soandso2�, if the name
contains �PNCD� jump to the same place.,

Etc., etc for a total of 4 decision makings.

Is this possible? I very much appreciate any suggestions.

Karo

#2

This might work.

tell application "Finder"
	try
		set target_fol to (first folder of desktop whose name begins with "proofs") as Unicode text
	on error e
		display dialog e
		return -- quit script
	end try
	set target_name to (get alias target_fol's name)'s text 7 thru end
end tell

set the clipboard to target_name as string -- is this really needed?

if target_name ends with "PYDVD" or target_name ends with "PYCD" then
	-- do something
	display dialog "PYDVD or PYCD"
else if target_name ends with "PNDVD" or target_name ends with "PNCD" then
	-- do something else
	display dialog "PNDVD or PNCD"
else if target_name ends with "OYDVD" or target_name ends with "OYCD" then
	-- do something else
	display dialog "OYDVD or OYCD"
else if target_name ends with "ONDVD" or target_name ends with "ONCD" then
	-- do something else
	display dialog "ONDVD or ONCD"
end if

– Rob