Finding Subfolder Names Missing Specific Content

Hi All: Due to circumstances I won’t go into to shorten this.
I have a large number of public domain e-books and after being away from the computer for a few months I find a large number are gone, kaput.
My e-books are in a folder called e-book Library. From there it is setup in structure via calibre; e-Book Library/Author/Book Title + calibre index no.
So an example of the tree looks like
e-Book Library
Anna Komene
The Alexiad (532)
The Alexiad - Anna Komene.epub
Arthur Machen
The Great God Pan (530)
As you can see the second entry has no e-book, but calibre still has its index number on the book’s subfolder.

I want to go through the sub-subfolders looking for ones that do not contain an e-book and put them into a list of book titles that I may later replace. My problem is getting the names of the Book Title folders that are missing e-books. I get lost in the methodology of doing this as I have never used subfolders, let alone subfolders within multiple subolders in my short experience of writing personal Applescripts.

Advance thanks for any tips, discussions, partial solutions and full solutions.

Note: My OS is OS X 10.11.6, but that is not in the drop down list here.

Model: Mac (27-inch, Mid 2011)
AppleScript: 2.5
Browser: Safari 601.6.17
Operating System: Mac OS X (10.10)

Good enough for one-off use:

set eBookFolder to (choose folder)

tell application "Finder"
	-- Get an alias list of the title folders.
	set titleFolders to folders of folders of eBookFolder as alias list
	-- Go through the list. If a folder contains any .epub files, replace its entry with 'missing value'.
	repeat with i from 1 to (count titleFolders)
		set thisFolder to item i of titleFolders
		if (name extension of thisFolder's files contains "epub") then set item i of titleFolders to missing value
	end repeat
end tell

-- Coerce the remaining aliases to a linefeed-delimited text listing the paths to the folders without .epub files.
set astid to AppleScript's text item delimiters
set AppleScript's text item delimiters to linefeed
set titleFolders to titleFolders's aliases as text
-- Remove the eBook folder path and trailing colon from each line, leaving just the author and title components.
set eBookFolderPath to eBookFolder as text
set AppleScript's text item delimiters to ":" & linefeed & eBookFolderPath
set authorsAndTitles to titleFolders's text items
set AppleScript's text item delimiters to linefeed
set authorsAndTitles to text ((count eBookFolderPath) + 1) thru -2 of (authorsAndTitles as text)
set AppleScript's text item delimiters to astid

return authorsAndTitles