Folder actions (excluding Unix "hidden" files)

Scripting Forums AppleScript | Mac OS X
,
#1

Hey all.

I got my script to work!!!

But I have a problem. How do I exclude the unix hidden files (the ones with a dot like .myfile.txt)

Here is my script.


on adding folder items to this_folder after receiving added_items
	
	repeat with the_video in added_items
		
		--Ensure video is fully there before continuing
		set previous_size to 0
		set current_size to 1
		
		repeat while previous_size ≠ current_size
			
			set previous_size to the size of (info for the_video)
			delay 10
			set current_size to the size of (info for the_video)
			
		end repeat
		-- The file should be done...
		
		-- Load the video on to the droplet...	
		tell application "Finder" to open the_video using the application file "Droplet.app" of this_folder
		
	end repeat
	
end adding folder items to
#2

try this


on adding folder items to this_folder after receiving added_items
	
	repeat with the_video in added_items
		if name of (info for the_video) does not start with "." then
			--Ensure video is fully there before continuing
			set previous_size to 0
			set current_size to 1	
			repeat while previous_size ≠ current_size	
				set previous_size to the size of (info for the_video)
				delay 10
				set current_size to the size of (info for the_video)	
			end repeat
			-- The file should be done...
			
			-- Load the video on to the droplet...	
			tell application "Finder" to open the_video using the application file "Droplet.app" of this_folder
		end if
	end repeat
	
end adding folder items to
#3

Thanks a bunch!!! That worked perfectly!!! Now to figure out how to make the droplet automatically submit!