Help a Noob with this Folder Creation Script

Scripting Forums AppleScript | Mac OS X
#1

I know I know use the search tool. Well I have been and I have got pretty far but im stuck. I have been creating this script to create folders on our server at work called “Graphics”. Where designers save their files making them available to all users. 2 things that I’m having problems with are If the user tries to create the file and is not connected to “Graphics” can I change that message to say something to effect of “Not Connected to Graphics Server.” Instead of “Cant make “Graphics” into type item”.
Using this great resource I have successfully integrated custom icons (removed them from this script). But I was also wondering if it is possible to have a header in the display dialog window. Like the application name.

Thanks in advance for any help.

tell application "Finder"
	set MasterNumber to text returned of (display dialog "Please Enter Master Number:" default answer "M1")
	set Client to text returned of (display dialog "Please Enter Client:" default answer "JWT")
	set Job to text returned of (display dialog "Please Enter Job Title:" default answer "Demo")
	set loc to "Graphics"
	set newfoldername to MasterNumber & "_" & Client & "_" & Job
	set newfo to make new folder at loc with properties {name:newfoldername}
	make new folder at newfo with properties {name:"AfterEffects"}
	make new folder at newfo with properties {name:"Audio"}
	make new folder at newfo with properties {name:"Combustion"}
	make new folder at newfo with properties {name:"Deko"}
	make new folder at newfo with properties {name:"Docs"}
	make new folder at newfo with properties {name:"Mac"}
	make new folder at newfo with properties {name:"SEQ"}
	make new folder at newfo with properties {name:"Targa"}
	set artw to make new folder at newfo with properties {name:"Interactive"}
	make new folder at artw with properties {name:"Flash"}
	make new folder at artw with properties {name:"Elements"}
	make new folder at artw with properties {name:"Video"}
end tell
#2

Instead of having it tell them that “Graphics” isn’t available, let AppleScript mount the drive

set loc to "Graphics"
set mountedVolumes to list disks
if mountedVolumes does not contain loc then
mount volume "afp://YourServerName/Graphics" as user name "" with password ""
end if

I don’t think you can add a header with display dialog. Display Alert allows a title, a message and automatically uses the icon of the current application; but it doesn’t allow for user input.

display alert "Drive Not Mounted" message "The " & loc & " drive isn't mounted. Please mount the drive and try again." as warning

Model: MacBookPro
Browser: Firefox 3.0.6
Operating System: Mac OS X (10.4)

#3

Hi,

display dialog has a with title parameter.
Additionally to bebout’s suggestion I recommend to let the shell create the folders on the server,
which is much faster and doesn’t bother the Finder

set loc to "Graphics"
set MasterNumber to text returned of (display dialog "Please Enter Master Number:" with title "myTitle" default answer "M1")
set Client to text returned of (display dialog "Please Enter Client:" default answer "JWT")
set Job to text returned of (display dialog "Please Enter Job Title:" default answer "Demo")
if loc is not in (do shell script "/bin/ls /Volumes") then
	try
		mount volume "afp://YourServerName/" & loc as user name "user" with password "¢¢¢¢"
	on error
		display alert "Drive Not Mounted" message "The " & loc & " drive isn't mounted. Please mount the drive and try again." as warning
	end try
end if
set newfoldername to MasterNumber & "_" & Client & "_" & Job
do shell script "/bin/mkdir -p " & quoted form of POSIX path of loc & "/" & newfoldername & "/{AfterEffects,Audio,Combustion,Deko,Docs,Mac,SEQ,Targa,Interactive/{Flash,Elements,Video}}/"
#4

Thank you!!! Thank you!!! Thank you!!! Will post If I have more questions.