iChat notification

I want an app that notifies me when someone comes online and when they become away. I want a dialog to display telling me who became available (online) or away.


Look under iChat preferences → Alerts. There you can set an AppleScript to run when an even occurs like Buddy became available/unavailable, etc.

beautiful, thanks!

You’re welcome.

Here is an extended version. Take out what you don’t want. This version logs activity as well.

#	Author: Craig Williams
#	Date:	2010-02-27 
#	Version: 0.1
#	Desc:	Keeps a log of buddies status and displays a dialog

using terms from application "iChat"
	on buddy became available theObject
		theResult("became", theObject)
	end buddy became available
	on buddy became unavailable theObject
		theResult("no longer", theObject)
	end buddy became unavailable
	on theResult(theStatus, theObject)
		# Log date and status
		set logPath to "$HOME/documents/ichat_status_log.txt"
		set theDate to (current date) as string
		set logText to "Buddy " & theStatus & " Available ::" & full name of theObject
		do shell script "echo " & quoted form of (theDate & " :: " & logText) & " >> " & logPath
		# Display dialog of status
		tell me to activate
		set displayText to "Buddy " & theStatus & " Available:" & return & full name of theObject
		display dialog displayText buttons {"OK"} giving up after 10
	end theResult
end using terms from

Thanks!!! Big Help!!! :):):):):):slight_smile:

Sorry for resurrecting an older thread…

This script seems to work well, but I’d like for each log entry to note which service the buddy is logging in with since I have buddies that use both AIM and Google Talk. How would you modify this script to include that in the log?