Hi
Im using the below to print from Adobe Indesign CS5 using a print preset,
the question is what code do I use to turn off colors that I do not want to print?.
tell application "Adobe InDesign CS5"
print active document using "175LPI-OS"
end tell
Ive been playing a bit more with presets and found that what I want is probably a no go, so ive shifted to using printing prefs as code below, but I still cannot find the right code to turn off colours before going to print.
The inks are all ways present as they are imported when I place PDF’s into ID.
set PathToDesktop to path to the desktop as text --for testing
--set PathToDesktop to "HotFolders:HW:" as text
tell application "Adobe InDesign CS5"
activate
tell active document
set horizontal measurement units of view preferences to millimeters
set vertical measurement units of view preferences to millimeters
tell document preferences
set pw to the page width
set ph to the page height
set document slug uniform size to true
set slug top offset to 0
end tell
set myName to (name of it) as text
set AppleScript's text item delimiters to {"."}
set fileBase to first text item of (myName as string)
set AppleScript's text item delimiters to {""}
set PS_file_path to (PathToDesktop & fileBase & ".ps") as text
tell print preferences
set printer to postscript file
set PPD to "Cobra 2-up"
set print file to PS_file_path
set color output to inRIP separations
set trapping to off
try
set bleed chain to true
set bleed top to 0
end try
set use document bleed to print to false
set include slug to print to false
set all printer marks to false
set tile to false
set page position to centered
set print page orientation to portrait
set paper size to custom
set paper height to ph
set paper width to pw
set download PPD fonts to true
set screening to "175 lpi/2540 dpi"
set flip to none
set font downloading to complete
set OPI image replacement to false
--set PostScript level to level 3
set print layers to visible printable layers
set print nonprinting to false
set print spreads to false
---------------------------------------------
-- TRIED THIS -- DOESNT WORK
---------------------------------------------
set NopRINT to ink "Keyline"
set print NopRINT to false
---------------------------------------------
--
---------------------------------------------
set scale mode to scale width height
set scale height to 100
set scale width to 100
set scale proportional to true
set send image data to optimized subsampling
set sequence to all
end tell
end tell
with timeout of 1800 seconds
print active document without print dialog
end timeout
tell active document to close saving yes
end tell
Hey, Budgie. Inks aren’t associated with the print dialog or preferences, they are controlled by the ink manager. If you want a specific ink to not print, toggle its print ink property.
gidday Marc
cheers for the heads up about using the “print ink property”, i ended up with the below which appears to do
the trick, just now need to add multiple colours to it, can my code be improved upon in any way Marc
tell application "Adobe InDesign CS5"
activate
set theDoc to active document
set NopRINT to "Keyline" as text
try
if exists NopRINT then
set (print ink of ink NopRINT of theDoc) to false
end if
on error
display dialog "no ink" as text
end try
end tell