I’m building a script to pull information from an MLS report and put it into a document. I pulled the text from the report and dropped it into a blank text frame in an InDesign document so I could search it. Here is a line from the text:
School Dist: Richardson ISD Living 1: 19X17 / 1 F Dining: 11X9 / 1 Mstr BR: 10X12 / 1
I need to find the room measurement 19x17 or 11x9 or 10x12 which will be counted as a single word in InDesign because there are no spaces
I know the measurement will follow Living 1: or F Dining: or Mstr BR:, but not necessarily what line it’s in.
so how do I find the measurement if I know what word or words it will follow?
(If it will help you to understand, the line for the report says:
-the school district for this home is Richardson ISD
-the first living space measures 19 x 17 and is on the first floor
-the formal dining room measures 11 x 9, also on the first floor
-the master bedroom is 10 x 12, on the first floor)
If you have the text then applescript’s text item delimiters (tid) can be used for this. If you’re not sure what they are then you need to learn about them because they’re very powerful, but basically it will take a string and turn it into a list of items. The items in the list will be separated by the tid. Normally the tid is “” so for example…
set theText to "some text"
set theList to text items of theText
-- without doing anything tids are ""
--> theList = {"s", "o", "m", "e", " ", "t", "e", "x", "t"}
But if you change the tid to something else before you get the text items of a string then you will get a different result such as…
set theText to "some text"
set AppleScript's text item delimiters to " " -- change tid to a space character
set theList to text items of theText
set AppleScript's text item delimiters to "" -- always change tid back when you're finished with them
--> theList = {"some", "text"} -- notice the list items were separated by the tid
Now that you understand about tid a little, this will do what you want…
set theText to "This is some text.
There are lots of sentences and paragraphs in this text.
School Dist: Richardson ISD Living 1: 19X17 / 1 F Dining: 11X9 / 1 Mstr BR: 10X12 / 1
I am not sure how to find the information."
set AppleScript's text item delimiters to "Living 1:"
set a to text items of theText
set livingRommSize to first word of (item 2 of a)
set AppleScript's text item delimiters to "F Dining:"
set a to text items of theText
set diningRoomSize to first word of (item 2 of a)
set AppleScript's text item delimiters to "Mstr BR:"
set a to text items of theText
set masterBedroomSize to first word of (item 2 of a)
set AppleScript's text item delimiters to ""
return {livingRommSize, diningRoomSize, masterBedroomSize}
Hank, it works perfectly in all cases, thank you.