make webloc from current website

Scripting Forums AppleScript | Mac OS X
#1

Hi

I like to have a Script that does what you can do manually by dragging the favicon to the desktop.

this is what I have so far:

tell application "Camino"
	tell front browser window
		set theurl to URL of current tab
		set theName to title of current tab as text
	end tell
end tell

tell application "System Events"
	
	set desk_path to (POSIX path of (path to desktop folder))
	
	-- create an empty property list dictionary item
	set the parent_dictionary to make new property list item with properties {kind:record}
	
	-- create new property list file using the empty dictionary list item as contents
	set the plistfile_path to (path to desktop folder as text) & theName
	
	set this_plistfile to ¬
		make new property list file with properties {contents:parent_dictionary, name:plistfile_path}
	
	
	-- add new property list items of each of the supported types
	make new property list item at end of property list items of contents of this_plistfile ¬
		with properties {kind:string, name:"URL", value:theurl}
	
	do shell script "mv " & desk_path & "/" & (quoted form of theName) & ".plist" & " " & desk_path & "/" & (quoted form of theName) & ".webloc"
	
	--get "mv " & desk_path & "/" & theName & ".plist" & " " & desk_path & "/" & theName & ".webloc"
	
	
end tell

at the moment I feel like I don’t see the wood for the trees. On some site it works good but on some sites it produces an Error at

make new property list item at end of property list items of contents of this_plistfile ¬
		with properties {kind:string, name:"URL", value:theurl}

I think it has something to do with special Characters or “/”…but I’m just guessing.

thanks for your help

Simon

Operating System: Mac OS X (10.5)

#2

Hi Simon,

isn’t this the same


tell application "Camino"
   tell front browser window
       set theurl to URL of current tab
       set theName to title of current tab as text
   end tell
end tell

tell application "Finder" to set webloc to make new internet location file to theurl at desktop with properties {name:theName}
#3

of course it is! THANKS

Und au viele dank für die andere antworte