Making a text file from a list of files

[rgardner]

I know this has been discussed before but forgive me because after hours of searching this site, I can’t find the answer I need.

I’m looking for a script that will simply allow me to choose a folder of files, copy each file and then write it to a text file (though just going to the clipboard would be fine, too).

I tried to modify a script by T.J. Mahaffey that was originally written for OS 9, but I can’t make it work in X.

Thanks in advance,
-Ryan

[Rob]

Does the script in this thread do what you want it to do? Here’s the code:

set output_ to (choose file name with prompt "Choose a name and location for the new file.") 
 set folder_ to (choose folder with prompt "Select the folder containing the text files.") 
 tell application "Finder" to set files_ to files of folder_ as alias list 
  
 try 
    set file_ref to open for access output_ with write permission 
    repeat with file_ in files_ 
       set text_ to read file_ 
       write (text_ & return) to file_ref starting at eof 
    end repeat 
    try 
       close access file_ref 
    end try 
 on error e 
    display dialog e 
    try 
       close access file_ref 
    end try 
 end try

– Rob

[rgardner]

Rob -

Not quite what I was after. I just need the filenames of the files, I don’t need the whole file copied. I didn’t make that very clear in my first post.

So if I have a folder of images 001.jpg, 002.jpg, 003.jpg my text document would just be a list of those filenames (preferrably separated by a return):
001.jpg
002.jpg
003.jpg

Thanks for your help.
-Ryan

[Rob]

Maybe this will work:

set output_ to (choose file name with prompt "Choose a name and location for the new file.")
set folder_ to (choose folder with prompt "Select the folder containing the files whose names should be collected.")
tell application "Finder" to set files_ to files of folder_ as alias list

set names_ to ""
repeat with file_ in files_
	set names_ to names_ & (name of (info for file_) & return)
end repeat

try
	set file_ref to open for access output_ with write permission
	write names_ to file_ref starting at eof
	try
		close access file_ref
	end try
on error e
	display dialog e
	try
		close access file_ref
	end try
end try

– Rob

[jonn8]

Here’s an alternate method that is a bit quicker but has the downside of not filtering out folder names (Rob’s solution will only grab file names) though if your folder only has files, this issue is moot:

–Open this script in a new Script Editor window.

set folder_list to list folder of (choose folder with prompt “Select a folder:”) without invisibles
tell (a reference to my text item delimiters)
set {old_delim, contents} to {contents, return}
set {folder_list, contents} to {“” & folder_list, old_delim}
end tell
do shell script "echo " & (quoted form of folder_list) & " > " & (quoted form of POSIX path of (choose file name with prompt “Save the file name list as:” default name “files.txt”))

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]

[rgardner]

Those both work perfectly as I will only have files, no sub folders, in my folders.

Thanks so much to both of you for quick and useful help.

That’s why I love – and have learned so much from – this site.

-Ryan

[Cody]

jon: Thank you for an easy way to write to a text file!

[jonn8]

Here is it in handler form:

–Open this script in a new Script Editor window.

set file_path to (choose file name with prompt “Save this file as:” default name “filename.txt”)
set the_string to “Some text”
set with_appending to false
my write_to_text_file(file_path, the_string, with_appending)

on write_to_text_file(file_path, the_string, with_appending)
–file_path can be a file reference, an alias to a file, or a file path as a string but be careful, it will overwrite existing files
–the_string must be a text string, this routine is only good for writing text files, use the standard AS write routines for writing other data types
if with_appending = true then
set the_pipe to " >> "
else
set the_pipe to " > "
end if
do shell script "echo " & (quoted form of the_string) & the_pipe & (quoted form of POSIX path of file_path)
end write_to_text_file

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]