Multiple selection referral problem

Scripting Forums AppleScript | Mac OS X
#1

I am attempting to get a choose from list setup going to select multiple items from a list, then display the choices and the related item in a corrasponding list. It works when I select blah, when I select blah and others, but not when don’t select blah. Its hard to explain, you just have to try the script to see what I mean. Please help.

set aList to {"blah", "green", "how", "now", "brown", "cow"}
set bList to {"blah1", "green2", "how3", "now4", "brown5", "cow6"}
set chList to choose from list aList with multiple selections allowed
set firstListCount to 1
if number of items in chList ≥ 1 then
	repeat with i from 1 to number of items in chList
		if item firstListCount of chList = item i of aList then
			set tempItem1 to ""
			set tempItem2 to ""
			set tempItem1 to tempItem1 & item firstListCount of aList
			set tempItem2 to tempItem2 & item i of bList
			display dialog "you selected " & tempItem1 & " which equals " & tempItem2
			set firstListCount to firstListCount + 1
		end if
	end repeat
end if

Thanks again.
Busy day today, 3 new topics posted.
Chuckles :smiley:

#2

I think this is what you want here:

set aList to {"blah", "green", "how", "now", "brown", "cow"}
set bList to {"blah1", "green2", "how3", "now4", "brown5", "cow6"}
set chList to choose from list aList with multiple selections allowed
repeat with aCh in chList
	repeat with k from 1 to count aList
		if item k of aList = contents of aCh then
			display dialog "you selected " & aCh & " which corresponds to " & item k of bList
			exit repeat
		end if
	end repeat
end repeat

Edited to add “exit repeat” no need to go on if you’ve found it.

More to the point:

set aList to {"blah", "green", "how", "now", "brown", "cow"}
set bList to {"blah1", "green2", "how3", "now4", "brown5", "cow6"}
set chList to choose from list aList with multiple selections allowed
set Equivs to {}
repeat with aCh in chList
	repeat with k from 1 to count aList
		if item k of aList = contents of aCh then
			set end of Equivs to item k of bList
			exit repeat
		end if
	end repeat
end repeat
Equivs
#3

Thanks thats exactly what I was looking for.
:D:D:D