is there a terminal command that gets your system info (basically the text you see when you click “about this mac”? i no nothing about terminal so…yeah…
You can get that from an AppleScript: “get system info”
If you want the whole nine yards (the equivalent of the system profiler’s output). It’s saved as text on your desktop:
tell application "Finder" to set tName to name of startup disk
do shell script "/usr/sbin/system_profiler > " & POSIX path of (path to desktop as text) & tName & ".profile.txt"
And this gets some other stuff:
set serial_number to do shell script "ioreg -c 'IOPlatformExpertDevice' | awk '/IOPlatformSerialNumber/ {print $4}' | cut -b 2-12"
set hardware_descr to do shell script "system_profiler SPHardwareDataType | grep 'Model' | cut -c 22-"
set machine_hw_name to do shell script "uname -m"
set processor_speed to (round ((system attribute "pclk") / 1000000)) --rounds to ones digit
set installed_RAM to (system attribute "ram ") / 1048 div 1000
set MacOS_version to (my gestalt_version_info("sysv", 4))
set starup_disk_name to (text 1 thru -2 of (path to startup disk as string))
set computer_name to do shell script "grep -A1 'ComputerName<' /Library/Preferences/SystemConfiguration/preferences.plist | grep -v key | cut -c 12-19"
set user_short_name to system attribute "USER"
set user_full_name to (do shell script "finger " & user_short_name & " | grep Login | colrm 1 46")
display dialog "Computer Name:" & tab & computer_name & return & "User Short Name:" & tab & user_short_name & return & "Serial Number:" & tab & serial_number & return & "Model Specs: " & tab & hardware_descr & return & "Processor Speed" & tab & processor_speed & return & "Installed RAM:" & tab & installed_RAM & "MB" & return & "Mac OS Version:" & tab & MacOS_version & return & "User Full Name:" & tab & user_full_name & return & "Startup Disk: " & tab & starup_disk_name
----------------------------------------------------------------------------------------------------------------------
----------------------------------------------------------------------------------------------------------------------
on num_to_hex(hex_data, string_length)
set hex_string to {}
repeat with i from string_length to 1 by -1
set hex_string to ((hex_data mod 16) as string) & hex_string
set hex_data to hex_data div 16
end repeat
return (hex_string as string)
end num_to_hex
on gestalt_version_info(gestalt_code, string_length)
try
copy my num_to_hex((system attribute gestalt_code), string_length) to {a, b, c, D}
if a = "0" then set a to ""
return (a & b & "." & c & "." & D) as string
on error
return "unknown"
end try
end gestalt_version_info