Noob iCal and folder action question

I know nothing about Applescripting… only a little more about Automator but I’m hoping someone can help me.

I’m trying to set up a folder action whereby when I add a new file to the folder in question an ical todo with alarm is created 60 days from the current date. Basically I want to set up a nag that will pop up 60 days from everytime I save a pdf to a folder.

Is this possible? Thanks

Browser: Mozilla/5.0 (Macintosh; U; Intel Mac OS X; en-US; rv:1.8.1) Gecko/20061024 BonEcho/2.0
Operating System: Mac OS X (10.4)

Hi,

try this (change “work” in the first line to your preferred calendar

property myCalendar : "work"

on adding folder items to this_folder after receiving these_items
	repeat with this_item in these_items
		set fName to name of (info for this_item)
		if fName does not start with "." then -- avoid new todo for .dsstore files or something similar 
			tell (current date) to set startTime to it - (its seconds) + 60 * days
			tell application "iCal"
				set newTodo to make new todo at beginning of todos of calendar myCalendar with properties {summary:fName, due date:startTime}
				tell newTodo
					make new display alarm at beginning of display alarms with properties {trigger date:startTime}
				end tell
			end tell
		end if
	end repeat
end adding folder items to

I think that’ll do it! Thanks so much!!