Photoshop CS2 Unsharp mask script won't compile Please help!

Scripting Forums AppleScript | Mac OS X
,
#1

I am trying to run a script that, among other things, uses the unsharp mask feature of photoshop CS2. But everything i’ve tried won’t even compile, let alone run.
Can someone please help?
I got this far.

tell application "Adobe Photoshop CS2"
	tell front document
		filter unsharp mask {amount:110, radius:1, threshold:10}
	end tell
end tell

This one actually compiled but didn’t work.
Chuckles :smiley:

#2

Chuckles66, supported objects of filters are “layers” so you will need to include this object in your script.
You example should look something like this:

tell application "Adobe Photoshop CS"
	tell front document
		filter layer 1 using unsharp mask with options ¬
			{amount:110, radius:1, threshold:10}
	end tell
end tell

Here’s my quick C&P file for working with filters in CS1 should cover the options available for how to reference the layers and also what options are available for each. Then all thats needed is to edit the option properties. Should come in useful even if you may have some extras in CS2.

tell application "Adobe Photoshop CS"
	set docRef to current document
	tell docRef
		-- Layer by index 1 being uppermost
		filter layer 1 using dust and scratches with options ¬
			{radius:2, threshold:30}
		-- Layer by "Name"
		filter layer "My Layer" using unsharp mask with options ¬
			{amount:120, radius:2, threshold:10}
		-- Layer of Layer Set by index 1 being uppermost
		filter layer 1 of layer set 1 using dust and scratches with options ¬
			{radius:2, threshold:30}
		-- Layer of Layer Set by "Names"
		filter layer "My Layer" of layer set "My Set" using unsharp mask with options ¬
			{amount:120, radius:2, threshold:10}
		-- Background Layer
		filter background layer using ocean ripple with options ¬
			{ripple size:4, ripple magnitude:6}
		-- Current Layer
		filter current layer using add noise with options ¬
			{amount:20, distribution:Gaussian, monochromatic:false}
		
		-- Filters with options
		-- Current Layer
		filter current layer using Gaussian blur with options ¬
			{radius:10}
		-- Current Layer
		filter current layer using add noise with options ¬
			{amount:5, distribution:Gaussian, monochromatic:false}
		-- Current Layer
		filter current layer using deinterlace with options ¬
			{eliminate:even fields, create new fields by:interpolation}
		-- Current Layer
		filter current layer using dust and scratches with options ¬
			{radius:2, threshold:12}
		-- Current Layer
		filter current layer using high pass with options ¬
			{radius:3}
		-- Current Layer
		filter current layer using lens flare with options ¬
			{brightness:130, flare center:{100, 50}, lens type:zoom}
		-- Current Layer
		filter current layer using maximum filter with options ¬
			{radius:5}
		-- Current Layer
		filter current layer using median noise with options ¬
			{radius:3}
		-- Current Layer
		filter current layer using minimum filter with options ¬
			{radius:5} -- Current Layer
		filter current layer using motion blur with options ¬
			{angle:35, radius:350}
		-- Current Layer
		filter current layer using ocean ripple with options ¬
			{ripple size:6, ripple magnitude:12}
		-- Current Layer
		filter current layer using radial blur with options ¬
			{amount:35, blur method:zoom, quality:best}
		-- Current Layer
		filter current layer using ripple with options ¬
			{amount:300, ripple size:medium}
		-- Current Layer
		filter current layer using smart blur with options ¬
			{radius:3, threshold:15, quality:high, mode:normal}
		-- Current Layer
		filter current layer using twirl with options ¬
			{angle:700}
		-- Current Layer
		filter current layer using unsharp mask with options ¬
			{amount:130, radius:3, threshold:18}
		-- Current Layer
		filter current layer using zigzag with options ¬
			{amount:-50, ridges:20, style:around center}
		
		-- Filters without options
		-- Current Layer
		filter current layer using NTSC colors
		-- Current Layer
		filter current layer using blur
		-- Current Layer
		filter current layer using blur more
		-- Current Layer
		filter current layer using clouds
		-- Current Layer
		filter current layer using despeckle
		-- Current Layer
		filter current layer using difference clouds
		-- Current Layer
		filter current layer using sharpen
		-- Current Layer
		filter current layer using sharpen edges
		-- Current Layer
		filter current layer using sharpen more
	end tell
end tell