[Quark] Setting for Overprint EPS Black & Full Resolution TIFF Output

Scripting Forums AppleScript | Mac OS X
#1

I couldn’t find any syntax to set the followings to true or false in Quark scripting for printing:-

Overprint EPS Black
Full Resolution TIFF Output

Could anyone please help! Thanks!

#2

cits, these are not part of the Quark dictionary (well at least with 6.5) what you may be able to do is script the GUI of the print dialog box capture those settings then continue with the rest of your set up then print. Here is a handler that should do this for you. It DOES require OSXA Extra Suites to perform some mouse clicks. You may be able to replace these with some vanilla applescript of your own but I find this OSXA much more reliable for this sort of stuff.

tell application "QuarkXPress"
	activate
	tell project 1
		set Layout_Name to name of active layout space
		my EPS_TIF_Options(Layout_Name)
		-- print etc
	end tell
end tell

-- Requires Extra Suites OSXA for better mouse clicking
on EPS_TIF_Options(Layout_Name)
	tell application "System Events"
		tell process "QuarkXPress"
			keystroke "p" using command down
			delay 0.5
			if exists window ("Print " & Layout_Name) then
				tell window ("Print " & Layout_Name)
					tell tab group 1
						tell radio button "Options"
							set {xPosition, yPosition} to position
							set {xSize, ySize} to size
						end tell
						tell application "Extra Suites"
							ES move mouse {xPosition + (xSize div 2), yPosition + (ySize div 2)}
							ES click mouse
						end tell
						delay 0.5
						tell group 1
							tell UI element 1
								tell UI element 3
									if (value of checkbox "Overprint EPS Black") = 0 then
										tell checkbox "Overprint EPS Black"
											set {xPosition, yPosition} to position
											set {xSize, ySize} to size
										end tell
										tell application "Extra Suites"
											ES move mouse {xPosition + (xSize div 2), yPosition + (ySize div 2)}
											ES click mouse
										end tell
									else
										-- Value = 1 is already enabled.
									end if
									if (value of checkbox "Full Resolution TIFF Output") = 0 then
										tell checkbox "Full Resolution TIFF Output"
											set {xPosition, yPosition} to position
											set {xSize, ySize} to size
										end tell
										tell application "Extra Suites"
											ES move mouse {xPosition + (xSize div 2), yPosition + (ySize div 2)}
											ES click mouse
										end tell
									else
										-- Value = 1 is already enabled.
									end if
								end tell
							end tell
						end tell
					end tell
					tell button "Capture Settings"
						set {xPosition, yPosition} to position
						set {xSize, ySize} to size
					end tell
					tell application "Extra Suites"
						ES move mouse {xPosition + (xSize div 2), yPosition + (ySize div 2)}
						ES click mouse
					end tell
				end tell
			end if
		end tell
	end tell
end EPS_TIF_Options
#3

Try using print styles, not sure if it is supported through AS. Not really even sure how to use them its been so long since I have used Quark…but it might be a better solution than GUI scripting.

#4

Print Styles are not part of the dictionary either. All my print styles including “default” have these 2 options set to on anyhow. The only problem being I can’t be 100% some monkey has not messed with this. If you are dealing with supplied files then it become anybodies guess.

#5

Thank you, Mark67.
I pick up more and more from your helps.
Thanks again.