QuickTime: Make one movie from all movs in folder?

Scripting Forums AppleScript | Mac OS X
#1

Hi!
I need help for a script that makes a reference movie from all movies in a folder.

There are nice skripts for QT, but I can’t bring them together to do what I want (sorry, I’m very new to AppleScript).

Can someone help me with that?

thank you,
k.

#2

hi again!
I’ve searched around to get some code together for merging videos from a folder to one video. I’m new to scripting, so it is very hard to understand the usage of the commands in the right order. :confused:

This is what I got right now:


tell application "Finder"
		set the theFolderPath to "SCREENDESIGN3_HD:Users:ZONE:Desktop:Quartz_VIennale:movs:" as alias
	set the movie_liste to list folder theFolderPath without invisibles
end tell

tell application "QuickTime Player"
	activate
	try
		stop every movie
		repeat with i from 1 to number of items in the movie_liste
			set this_item to item i of the movie_liste
			set this_item to (theFolderPath & this_item) as alias
			open this_item
			
			tell movie 1
				rewind
				select all
				copy
				select none
			end tell
			close movie 1 saving no
			
			open alias "SCREENDESIGN3_HD:Users:ZONE:Desktop:Quartz_VIennale:mov.mov"
			set mov_mov to name of movie 1
			tell mov_mov
				select none
				set the current time of mov_mov to the duration of mov_mov
				add
				select none
				select at 0 to 0
			end tell
			close mov_mov saving yes
		end repeat
	end try
end tell

I would be very happy if someone got a clue how to get it work?
zone

#3

Try something like this:

choose folder with prompt "Merge all .mov files in this folder:"
set sourceFolder to result

choose file name with prompt "Saved resulting .mov file as:" default location sourceFolder default name "Merge.mov"
set outputFile to (result as Unicode text)

if (text -4 through -1 of result) is not ".mov" then set outputFile to outputFile & ".mov"
set outputFile to outputFile as file specification

tell application "Finder"
	launch
	set movList to (files of sourceFolder whose name extension is "mov") as alias list
end tell

tell application "QuickTime Player"
	activate
	
	try
		close every window
	end try
	
	make new movie
	set errors to ""
	
	repeat with thisItem in movList
		try
			open thisItem
			
			tell movie 1
				rewind
				select all
				copy
				select none
				close saving no
			end tell
			
			tell movie 1 to add
		on error errMsg number errNum
			set errors to errors & (thisItem as Unicode text) & return
		end try
	end repeat
	
	if errors is not "" then
		display dialog "Errors were encountered with these files:" & return & return & errors buttons {"Cancel", "Continue"} default button 2
	end if
	
	tell movie 1
		select none
		rewind
		save self contained in outputFile
	end tell
end tell

beep 2
#4

thank you very much!
this works.

i don’t have time now to continue but i want to add it as a folder action and everytime a new movie is added it is executed.

thanks again.

zone