Renameing items in a list

Scripting Forums AppleScript | Mac OS X
#1

I could never get this down.

I have a list containing items like pstyle:CO,pstyle:TX that need to be renamed to dps:CO, dps:TX

I assume i need to use the set AppleScript’s text item delimiters to But thats the part I could never understand. BTW if there is an easier or fast way then that I am all for it.

Thanks

#2

You could do something like this:

set test to {"<pstyle:CO>", "<pstyle:TX>"}

set ASTID to AppleScript's text item delimiters
repeat with thisItem in test
	set AppleScript's text item delimiters to "pstyle"
	set thisItem's contents to every text item of thisItem's contents
	set AppleScript's text item delimiters to "dps"
	set thisItem's contents to (thisItem's contents as text)
end repeat
set AppleScript's text item delimiters to ASTID

return test

Edit: You can also do it like this:

set test to {"<pstyle:CO>", "<pstyle:TX>"}

set firstDelimiter to "..." -- use something that won't appear in list

set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to firstDelimiter
set test to (every text item of test) as text
set AppleScript's text item delimiters to "pstyle"
set test to (every text item of test)
set AppleScript's text item delimiters to "dps"
set test to (test as text)
set AppleScript's text item delimiters to firstDelimiter
set test to (every text item of test)
set AppleScript's text item delimiters to ASTID

return test
#3

Or perhaps like this:

to switchStrings of l from s to r
	set d to text item delimiters
	set text item delimiters to return
	tell l to set l to beginning & ({""} & rest)
	set text item delimiters to s
	set l to l's text items
	set text item delimiters to r
	tell l to set l to beginning & ({""} & rest)
	set text item delimiters to d
	l's paragraphs
end switchStrings

set test to {"<pstyle:CO>", "<pstyle:TX>"}

switchStrings of test from "pstyle" to "dps"
--> {"<dps:CO>", "<dps:TX>"}