Script to turn iCal into background

[Jmax]

Ok, what I want is to have a script that activates when I quit iCal. If need be, I can just run it from the finder. Here is what I want the script to do. When I have iCal open, I use the month view. I want to take a picture of that and put it onto my screen as the background image. Then I want it to save and quit iCal.

If this is just too much for one script, please feel free to let me know. I may be just ____ing in the wind, for all I know. I have been scripting for several years.But I have not been scripting in OS X. None of my scripts seem to work in it. I am guessing that I am missing a basic premise somewhere in the difference between scripting OS 9 and OS X.

I am hoping to learn from this. My last few requests for help got me sent to find someone else’s script that already does what I need. That doesn’t help much. But as it happened, it was the most expiditious thing to do at the time. This time, I want to learn. So any tips or direction I can get on this script would be MORE than appreciated.

Thank you to anyone who feels like helping me transition.

[jonn8]

This is a quick patchwork of some code snippets I’ve had lying around (it can surely be optimized):

–Open this script in a new Script Editor window.

tell application “iCal”
activate
switch view to month view
view calendar at (current date)
try
tell application “System Events”
tell process “iCal” to click menu item “Hide Info” of menu “Window” of menu bar item “Window” of menu bar 1
end tell
end try
set zoomed of window 1 to true
end tell

set target_folder to (path to temporary items) as string
set file_prefix to “sc_”
set sc_num to 0
tell application “Finder”
repeat
set sc_num to sc_num + 1
set file_name to file_prefix & sc_num & “.pdf”
if (exists of file (target_folder & file_name)) = false then exit repeat
end repeat
end tell
do shell script "/usr/sbin/screencapture -x " & (quoted form of POSIX path of ((target_folder & file_name) as string))

try
tell application “iCal” to quit
end try

tell application “Finder”
set desktop_picture_old to (desktop picture) as alias
set desktop picture to file (target_folder & file_name)
activate
try
set visible of (every process whose visible = true and frontmost = false) to false
end try
set the_button to button returned of (display dialog “Use this image or revert?” buttons {“Revert”, “OK”} default button 2 with icon 1)
if the_button = “Revert” then set desktop picture to desktop_picture_old
end tell

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]

[Jmax]

When I come to this line

tell process “iCal” to click menu item “Hide Info” of menu “Window” of menu bar item “Window” of menu bar 1

it highlights ‘menu item’ and says:

“Expected end of line but found class name.” Am I missing some osax, or does AS still use these? I don’t know. I have been out of it for a while and I think everything just took off without me.

Thanks for your help.

Jeff