Searching contents of a set variable

Scripting Forums AppleScript | Classic Mac OS
#1

I’m not entirely clear as to what you want. This script takes a bunch of folder selections from the user and looks for a particular filename in each one until it either finds one or runs out of folders:

set fldrList to {}
set doneFlg to false
repeat until doneFlg
	try
		set srchFldr to (choose folder with prompt "Select folder to search:") as text
		set end of fldrList to srchFldr
	on error m number n
		if n is -128 then
			set doneFlg to true
		else
			error m number n
		end if
	end try
end repeat
set fileName to text returned of (display dialog "Enter the file name:" default answer "")
repeat with aFldr in fldrList
	set srchFldr to (aFldr as text)
	set fndFlg to false
	try
		alias (srchFldr & fileName)
		set fndFlg to true
	end try
	if fndFlg then
		display dialog "I found it!" & return & srchFldr
		exit repeat
	end if
end repeat
if not fndFlg then
	display dialog "It wasn't in any of the folders"
end if