Set item as a list?

Scripting Forums AppleScript | Mac OS X
#1 
set dtF to paragraphs of (do shell script "ls -F ~/Desktop | grep '/' | cut -d'/' -f1")
set tc to (count dtF)
repeat with i from 1 to tc
	set folderName to item i of dtF --<:  is the folder name, no need to use text item delimiters -->":"
	
	if folderName does not start with "2_" and folderName does not start with "Hot" and folderName does not start with "Press" and folderName does not start with "Design" and folderName does not start with "Keywords" and folderName does not start with "Season" and folderName does not start with "Sue" and folderName does not start with "Design" then
		
		set {oldTID, my text item delimiters} to {my text item delimiters, "_WK"}
		set FolderEndName to last text item of folderName
		set brandName to first text item of folderName
		set my text item delimiters to "_PSD"
		set weekNumber to first text item of FolderEndName
		set my text item delimiters to oldTID
		log brandName
	end if	
end repeat

After this I want to be able to set the brandToUse as as list. to have the same output as this. How might I do this?

I tried this > set brandsToUse to brandName as list but this returns only the last item

set brandsToUse to choose from list {"BA", "Bu", "Da", "Do", "Di", "Fr"} with prompt "Choose brands to send out." with multiple selections allowed
log brandsToUse
#2

Your last script fragment does return a list in the variable brandsToUse and when I log it, my log shows a list as well, so the question is does the first part deliver a list?

#3

I think mcquiff may be asking how to gather the brand names extracted during the repeat:

set dtF to paragraphs of (do shell script "ls -F ~/Desktop | grep '/' | cut -d'/' -f1")

set allBrands to {} -- Start a list in which to collect the brand names.
set tc to (count dtF)
repeat with i from 1 to tc
	set folderName to item i of dtF --<:  is the folder name, no need to use text item delimiters -->":"
	
	if folderName does not start with "2_" and folderName does not start with "Hot" and folderName does not start with "Press" and folderName does not start with "Design" and folderName does not start with "Keywords" and folderName does not start with "Season" and folderName does not start with "Sue" then -- You had "Design" twice here.
		
		set {oldTID, my text item delimiters} to {my text item delimiters, "_WK"}
		set FolderEndName to last text item of folderName
		set brandName to first text item of folderName
		set end of allBrands to brandName -- Append this brand name to the brand name list.
		
		set my text item delimiters to "_PSD"
		set weekNumber to first text item of FolderEndName -- What do you want to do with this?
		set my text item delimiters to oldTID
	end if
end repeat

set brandsToUse to (choose from list allBrands with multiple selections allowed)
if (brandsToUse is false) then error number -128 -- Explicit cancel needed with 'choose from list' "Cancel" button.
log brandsToUse
#4

Sorry yes all a bit confusing the last post was right although I didn’t need to use the dialog to prompt the user again simply use the varible allBrands!

Many Thanks

Matt